Phong光照模型
进入摄像机的光线分为四个部分:
环境光(ambient)
其他所有间接光照
自发光(emissive)
给定一个方向,模型表面本身向该方向发射多少辐射量
漫反射(diffuse)
当光线从光源照射到模型表面时,会向所有方向散射多少辐射量
高光反射(specular)
当光线从光源照射到模型表面时,会向镜面反射方向散射多少辐射量
Blinn-Phong模型:引入半程向量来计算高光反射,能得到更好的结果
Blinn-Phong模型是各向同性(isotropic)的,固定视角和光源方向旋转表面时,反射不会发生变化。
逐像素光照:Phong着色(Phong shading)
使用每个像素的法线(对顶点法线插值得到 或法线纹理中采样得到)进行光照模型的计算
逐顶点光照:高洛德着色(Gouraud shading)
只在顶点上计算光照,将结果进行线性插值得到像素颜色,无法计算高光反射
且会导致图元内部的颜色暗于顶点处的最高颜色值,可能会产生棱角现象
但是计算量很小。
逐顶点光照 (Gouraud shading)
Shader "Custom/DiffuseVertex"
{
Properties
{
_Diffuse ("Diffuse", Color) = (1,1,1,1)
}
SubShader
{
Pass{
Tags { "RenderType"="ForwardBase" }
CGPROGRAM
//指定顶点着色器的函数
#pragma vertex vert
//指定片元着色器的函数
#pragma fragment frag
#include "Lighting.cginc"
struct a2v{ //顶点着色器的输入
float4 vertex: POSITION; //顶点坐标
float3 normal:NORMAL; //顶点法线
};
struct v2f{ //顶点着色器的输出,片元着色器的输入
float4 pos:SV_POSITION;
float3 color:COLOR;
};
fixed4 _Diffuse;
v2f vert(a2v v)
{
v2f o;
o.pos=UnityObjectToClipPos(v.vertex); //使用内建函数实现MVP变换
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz; //使用内置宏获取环境光照
fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject)); //法线 的世界坐标
fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz); //光方向矢量 的世界坐标
//saturate函数可以对矢量的每一个分量截取在[0,1]范围内
fixed3 diffuse=_LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));
o.color=ambient+diffuse; //加上环境光照
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
return fixed4(i.color,1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}
逐像素光照 (Phong shading)
Shader "Custom/DiffusePixel"
{
Properties
{
_Diffuse ("Diffuse", Color) = (1,1,1,1)
_Specular("Specular",Color)=(1,1,1,1)
_Gloss("Gloss",Range(8.0,256))=20
}
SubShader
{
Pass{
Tags { "RenderType"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
struct a2v{
float4 vertex: POSITION;
float3 normal:NORMAL;
};
struct v2f{
float4 pos:SV_POSITION;
float3 worldNormal:TEXCOORD0;
float3 worldPos:TEXCOORD1;
};
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
v2f vert(a2v v)
{
v2f o;
o.pos=UnityObjectToClipPos(v.vertex);
o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz; //顶点变换到世界空间,并截取3x3矩阵
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
fixed3 worldNormal=normalize(i.worldNormal); //法线向量归一化
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz; //环境光照
fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz); //指向光源的方向向量世界坐标
//saturate函数可以对矢量的每一个分量截取在[0,1]范围内
fixed lambert=saturate(dot(worldNormal,worldLight)); //兰伯特光照模型
float halfLambert=dot(worldNormal,worldLight)*0.5+0.5; //半兰伯特光照模型
fixed3 diffuse=_LightColor0.rgb * _Diffuse.rgb * halfLambert; //计算漫反射(使用半兰伯特模型)
return fixed4(ambient+diffuse,1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}
镜面反射(高光反射)
在上述基础上增加了specular分量的计算,使用半程向量,可以不用计算反射光线。同时也给出了计算反射光线的方法。
逐像素光照
Shader "Custom/DiffusePixel"
{
Properties
{
_Diffuse ("Diffuse", Color) = (1,1,1,1)
_Specular("Specular",Color)=(1,1,1,1)
_Gloss("Gloss",Range(8.0,256))=20
}
SubShader
{
Pass{
Tags { "RenderType"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
struct a2v{
float4 vertex: POSITION;
float3 normal:NORMAL;
};
struct v2f{
float4 pos:SV_POSITION;
float3 worldNormal:TEXCOORD0;
float3 worldPos:TEXCOORD1;
};
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
v2f vert(a2v v)
{
v2f o;
o.pos=UnityObjectToClipPos(v.vertex);
o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz; //顶点变换到世界空间,并截取3x3矩阵
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
fixed3 worldNormal=normalize(i.worldNormal); //法线向量归一化
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz; //环境光照
fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz); //指向光源的方向向量世界坐标
//saturate函数可以对矢量的每一个分量截取在[0,1]范围内
fixed lambert=saturate(dot(worldNormal,worldLight)); //兰伯特光照模型
float halfLambert=dot(worldNormal,worldLight)*0.5+0.5; //半兰伯特光照模型
fixed3 diffuse=_LightColor0.rgb * _Diffuse.rgb * halfLambert; //计算漫反射(使用半兰伯特模型)
fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz); //视线,从像素到摄像机
fixed3 reflectDir=normalize(reflect(-worldLight,worldNormal)); //计算反射光线方向
fixed3 halfDir=normalize(worldLight+viewDir); //半程向量
fixed3 specular_phong = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss); //使用Phong模型计算的高光
fixed3 specular_blinn = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(halfDir,worldNormal)),_Gloss); //使用Blinn-Phong模型计算的高光
return fixed4(ambient+diffuse+specular_blinn,1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}
纹理
单一纹理贴图
Shader "Custom/SingleTexture"
{
Properties
{
_Color ("Color", Color) = (1,1,1,1) //控制物体整体色调
_Specular ("Specular",Color) = (1,1,1,1)
_Gloss ("Gloss",Range(8.0,256)) = 20
_MainTex ("Main Tex",2D)="white" {} //使用的纹理贴图
}
SubShader
{
Pass{
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
struct a2v{
float4 vertex: POSITION;
float3 normal:NORMAL;
float4 texcoord:TEXCOORD0;
};
struct v2f{
float4 pos:SV_POSITION; //裁剪空间坐标
float3 worldNormal:TEXCOORD0; //世界空间坐标
float3 worldPos:TEXCOORD1;
float2 uv:TEXCOORD2;
};
fixed4 _Color;
fixed4 _Specular;
float _Gloss;
sampler2D _MainTex;
float4 _MainTex_ST; //纹理的缩放和平移值
v2f vert(a2v v)
{
v2f o; //顶点着色器输出
o.pos=UnityObjectToClipPos(v.vertex);
o.worldNormal=UnityObjectToWorldNormal(v.normal);
o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
o.uv=v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; //乘以缩放矩阵,再加上平移量
//或者可以使用内置宏:
//o.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
fixed3 worldNormal=normalize(i.worldNormal);
fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos)); //使用内置函数得到光线矢量
fixed3 albedo=tex2D(_MainTex,i.uv).rgb * _Color.rgb; //从纹理中获得计算漫反射使用的颜色
fixed3 diffuse=albedo*_LightColor0.rgb*max(0,dot(worldNormal,worldLightDir)); //计算漫反射颜色
fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed3 halfDir=normalize(worldLightDir+viewDir); //计算半程向量
fixed3 specular=_LightColor0.rgb * _Specular.rgb *pow(max(0,dot(worldNormal,halfDir)),_Gloss);
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz * albedo; //计算环境光照
return fixed4(ambient+diffuse+specular,1.0);
}
ENDCG
}
}
FallBack "Specular"
}
法线贴图
在顶点的切线空间中计算
Shader "Custom/NormalMap_TangentSpace"
{
Properties
{
_Color ("Color Tint", Color) = (1,1,1,1) //控制整体色调
_MainTex ("Main Tex", 2D) = "white" {} //光照贴图
_BumpMap ("Normal Map",2D)="bump" {} //法线纹理
_BumpScale ("Bump Scale",Float)=1.0
_Specular ("Specular", Color)=(1,1,1,1)
_Gloss ("Gloss", Range(0,255)) = 10
}
SubShader
{
Pass{
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
// Physically based Standard lighting model, and enable shadows on all light types
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "UnityCG.cginc"
fixed4 _Color;
fixed4 _Specular;
float _Gloss;
sampler2D _MainTex;
float4 _MainTex_ST; //纹理的缩放和平移值
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale; //控制凹凸程度
struct a2v{
float4 vertex: POSITION;
float3 normal:NORMAL;
float4 tangent:TANGENT; //切线方向
float4 texcoord:TEXCOORD0; //_MainTex和_BumpMap 通常使用同一组纹理坐标
};
struct v2f{
float4 pos:SV_POSITION; //裁剪空间坐标
float4 uv:TEXCOORD0; //xy存储光照贴图的纹理坐标,zw存储法线贴图的纹理坐标
float3 lightDir:TEXCOORD1; //光照方向
float3 viewDir:TEXCOORD2; //视角方向k
};
v2f vert(a2v v)
{
v2f o; //顶点着色器输出
o.pos=UnityObjectToClipPos(v.vertex);
o.uv.xy=v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; //纹理坐标乘以纹理的缩放加上平移
o.uv.zw=v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw; //法线贴图坐标乘以缩放加上平移
//用z轴(法线)叉乘x轴(切线)来计算y轴(副切线)的方向
float3 binormal=cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;
//构造切线空间到模型空间的变换矩阵
float3x3 rotation=float3x3(v.tangent.xyz,binormal,v.normal);
//把光照方向和视角方向变换到切线空间
o.lightDir=mul(rotation,ObjSpaceLightDir(v.vertex));
o.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex));
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
fixed3 tangentLightDir=normalize(i.lightDir); //切线空间下的光照方向
fixed3 tangentViewDir=normalize(i.viewDir); //切线空间下的观察方向
fixed4 packedNormal=tex2D(_BumpMap,i.uv.zw); //从法线贴图中采样得到切线空间下的法线
fixed3 tangentNormal;
tangentNormal.xy=(packedNormal.xy*2-1)*_BumpScale;
tangentNormal.z=sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy))); //z^2=1-(x^2+y^2)
//如果在Unity中把法线纹理的类型设置成Normal_Map,可以使用内置宏:
//tangentNormal=UnpackNormal(packedNormal);
//tangentNormal.xy*=_BumpScale
//tangentNormal.z=sqrt(1.0-saturate(dot((tangentNormal.xy,tangentNormal.xy)))); //z^2=1-(x^2+y^2)
fixed3 albedo=tex2D(_MainTex,i.uv).rgb * _Color.rgb; //从纹理中获得计算漫反射使用的颜色
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz * albedo; //计算环境光照
fixed3 diffuse=albedo*_LightColor0.rgb*max(0,dot(tangentNormal,tangentLightDir)); //在切线空间中计算漫反射颜色
fixed3 halfDir=normalize(tangentLightDir+tangentViewDir); //半程向量
//在切线空间中计算高光
fixed3 specular=_LightColor0.rgb * _Specular.rgb *pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
return fixed4(ambient+diffuse+specular,1.0);
}
ENDCG
}
}
FallBack "Specular"
}
在世界空间中计算(推荐)
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
Shader "Custom/NormalMap_WorldSpace"
{
Properties
{
_Color ("Color Tint", Color) = (1,1,1,1) //控制整体色调
_MainTex ("Main Tex", 2D) = "white" {} //基本纹理贴图
_BumpMap ("Normal Map",2D)="bump" {} //法线纹理
_BumpScale ("Bump Scale",Float)=1.0 //凹凸程度
_Specular ("Specular", Color)=(1,1,1,1)
_Gloss ("Gloss", Range(0,255)) = 10
}
SubShader
{
Pass{
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
// Physically based Standard lighting model, and enable shadows on all light types
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "UnityCG.cginc"
fixed4 _Color;
fixed4 _Specular;
float _Gloss;
sampler2D _MainTex;
float4 _MainTex_ST; //纹理贴图的缩放和平移值
sampler2D _BumpMap;
float4 _BumpMap_ST; //法线贴图的缩放和平移值
float _BumpScale;
struct a2v{
float4 vertex: POSITION;
float3 normal:NORMAL;
float4 tangent:TANGENT; //切线方向,w分量存储旋向性,用于确定副切线的方向性
float4 texcoord:TEXCOORD0; //_MainTex和_BumpMap 通常使用同一组纹理坐标
};
struct v2f{
float4 pos:SV_POSITION; //裁剪空间坐标
float4 uv:TEXCOORD0; //xy存储光照贴图的纹理坐标,zw存储法线贴图的纹理坐标
float4 TtoW0: TEXCOORD1; //分开存储切线空间到世界空间的变换矩阵
float4 TtoW1: TEXCOORD2;
float4 TtoW2: TEXCOORD3;
};
v2f vert(a2v v)
{
v2f o; //顶点着色器输出
o.pos=UnityObjectToClipPos(v.vertex);
o.uv.xy=v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; //纹理坐标乘以纹理的缩放加上平移
o.uv.zw=v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw; //法线贴图坐标乘以缩放加上平移
float3 worldPos=mul(unity_ObjectToWorld,v.vertex);
fixed3 worldNormal=UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent=UnityObjectToWorldDir(v.tangent.xyz);
//用z轴(法线)叉乘x轴(切线)来计算y轴(副切线)的方向
fixed3 worldBinormal=cross(worldNormal,worldTangent) * v.tangent.w;
//切线空间变换到世界空间的变换矩阵,前三列是切线空间的坐标轴在世界空间下的表达
//因为只需要变换向量(法线),不需要计算平移,只需要3x3的矩阵, w分量可以用于存储worldPos
o.TtoW0=float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
o.TtoW1=float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
o.TtoW2=float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
float3 worldPos=float3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w);
fixed3 lightDir=normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir=normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 bump=UnpackNormal(tex2D(_BumpMap,i.uv.zw));
bump.xy*=_BumpScale;
bump.z=sqrt(1.0-saturate(dot(bump.xy,bump.xy)));
//左乘变换矩阵,等于和每一行的行向量进行点乘,得到世界空间中的法线
bump=normalize(half3(dot(i.TtoW0.xyz,bump),dot(i.TtoW1.xyz,bump),dot(i.TtoW2.xyz,bump)));
fixed3 albedo=tex2D(_MainTex,i.uv).rgb * _Color.rgb; //从纹理中获得计算漫反射使用的颜色
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz * albedo; //计算环境光照
fixed3 diffuse=albedo*_LightColor0.rgb*max(0,dot(bump,lightDir)); //计算漫反射颜色
fixed3 halfDir=normalize(lightDir+viewDir); //半程向量
//计算高光
fixed3 specular=_LightColor0.rgb * _Specular.rgb *pow(max(0,dot(bump,halfDir)),_Gloss);
return fixed4(ambient+diffuse+specular,1.0);
}
ENDCG
}
}
FallBack "Specular"
}
参考
- 冯乐乐 《Unity Shader 入门精要》