hive parquet 压缩 文件 hive数据压缩格式

文章目录

• Hive中的压缩

• 1、Hadoop压缩配置

• 1.1 MR支持的压缩编码
• 1.2 压缩参数配置

• 2、开启你Map输出阶段压缩（MR引擎）
• 3、开启你Reduce输出阶段压缩

• Hive中的存储

• 1、文件存储格式
• 2、行式存储和列式存储

• TextFile格式
• Orc格式

• 主流文件存储格式实验

• 默认存储格式和不带压缩
• ORC存储格式和不带压缩
• ORC存储格式和Snappy压缩
• 总结

Hive中的压缩

1、Hadoop压缩配置

1.1 MR支持的压缩编码

压缩格式	算法	文件扩展名	是否可切分
DEFLATE	DEFLATE	.deflate	否
Gzip	DEFLATE	.gz	否
bzip2	bzip2	.bz2	是
LZO	LZO	.lzo	是
Snappy	Snappy	.snappy	否

为了支持多种压缩/解压缩算法，Hadoop引入了编码/解码器，如下表所示：

Hadoop 查看支持压缩的方式 hadoop checknative

Hadoop 在driver端设置压缩

压缩格式	对应的编码/解码器
DEFLATE	org.apache.hadoop.io.compress.DefaultCodec
gzip	org.apache.hadoop.io.compress.GzipCodec
bzip2	org.apache.hadoop.io.compress.BZip2Codec
LZO	com.hadoop.compression.lzo.LzopCodec
Snappy	org.apache.hadoop.io.compress.SnappyCodec

1.2 压缩参数配置

要在Hadoop中启用压缩，可以配置如下参数（mapred-site.xml文件中）：

参数	默认值	阶段	建议
io.compression.codecs （在core-site.xml中配置）	org.apache.hadoop.io.compress.DefaultCodec, org.apache.hadoop.io.compress.GzipCodec, org.apache.hadoop.io.compress.BZip2Codec, org.apache.hadoop.io.compress.Lz4Codec	输入压缩	Hadoop使用文件扩展名判断是否支持某种编解码器
mapreduce.map.output.compress	false	mapper输出	这个参数设为true启用压缩
mapreduce.map.output.compress.codec	org.apache.hadoop.io.compress.DefaultCodec	mapper输出	使用LZO、LZ4或snappy编解码器在此阶段压缩数据
mapreduce.output.fileoutputformat.compress	false	reducer输出	这个参数设为true启用压缩
mapreduce.output.fileoutputformat.compress.codec	org.apache.hadoop.io.compress. DefaultCodec	reducer输出	使用标准工具或者编解码器，如gzip和bzip2

2、开启你Map输出阶段压缩（MR引擎）

目的：可以减少job中map和Reduce task间数据传输量。

--开启hive中间传输数据压缩功能
hive (default)>set hive.exec.compress.intermediate=true;
--开启mapreduce中map输出压缩功能
hive (default)>set mapreduce.map.output.compress=true;
--设置mapreduce中map输出数据的压缩方式
hive (default)>set mapreduce.map.output.compress.codec=org.apache.hadoop.io.compress.SnappyCodec;
--执行查询语句查看效果
hive (default)> select count(ename) name from emp;

3、开启你Reduce输出阶段压缩

--开启hive最终输出数据压缩功能
hive (default)>set hive.exec.compress.output=true;
--开启mapreduce最终输出数据压缩
hive (default)>set mapreduce.output.fileoutputformat.compress=true;
--设置mapreduce最终数据输出压缩方式
hive (default)> set mapreduce.output.fileoutputformat.compress.codec =org.apache.hadoop.io.compress.SnappyCodec;
--测试一下输出结果是否是压缩文件
insert overwrite local directory '/home/hadoop/test/ys' select * from emp  sort by deptno desc;

Hive中的存储

1、文件存储格式

1. 文件分两种类型：行式存储和列式存储，列存要比行存用的多；
2. 四种存储类型：TEXTFILE和SEQUENCEFILE的存储格式都是基于行存储的；ORC和PARQUET是基于列式存储的；
3. ORC是TEXTFILE的列存，PARQUET是SEQUENCEFILE列存。

当你在公司里使用mr做引擎玩数仓的时候，你文件存储格式可以为orc+lzo；
当你在公司里使用spark做引擎玩数仓的时候，你文件存储格式可以为parquet+snappy。

2、行式存储和列式存储

行存储的特点：

查询满足条件的一整行数据的时候，列存储则需要去每个聚集的字段找到对应的每个列的值，行存储只需要找到其中一个值，其余的值都在相邻地方，所以此时行存储查询的速度更快 。

列存储的特点：

因为每个字段的数据聚集存储，在查询只需要少数几个字段的时候，能大大减少读取的数据量；每个字段的数据类型一定是相同的，列式存储可以针对性的设计更好的设计压缩算法。

TextFile格式

默认格式，数据不做压缩，磁盘开销大，数据解析开销大。可结合Gzip、Bzip2使用，但使用Gzip这种方式，hive不会对数据进行切分，从而无法对数据进行并行操作。

Orc格式

Orc (Optimized Row Columnar)

每个Orc文件由1个或多个stripe组成，每个stripe一般为HDFS的块大小，每一个stripe包含多条记录，这些记录按照列进行独立存储，对应到Parquet中的row group的概念。每个Stripe里有三部分组成，分别是Index Data，Row Data，Stripe Footer

1）Index Data：一个轻量级的index，默认是每隔1W行做一个索引。这里做的索引应该只是记录某行的各字段在Row Data中的offset。

2）Row Data：存的是具体的数据，先取部分行，然后对这些行按列进行存储。对每个列进行了编码，分成多个Stream来存储。

3）Stripe Footer：存的是各个Stream的类型，长度等信息。

每个文件有一个File Footer，这里面存的是每个Stripe的行数，每个Column的数据类型信息等；每个文件的尾部是一个PostScript，这里面记录了整个文件的压缩类型以及FileFooter的长度信息等。在读取文件时，会seek到文件尾部读PostScript，从里面解析到File Footer长度，再读FileFooter，从里面解析到各个Stripe信息，再读各个Stripe，即从后往前读。

主流文件存储格式实验

默认存储格式和不带压缩

1、创建表

create table log_text (
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as textfile; --存储数据格式为TEXTFILE

2、上传数据

load data local inpath '/home/hadoop/test/log.data' into table log_text ;

3、查看大小

dfs -du -h /user/hive/warehouse/log_text;

ORC存储格式和不带压缩

1、创建表

create table log_orc (
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc --存储数据格式为TEXTFILE
tblproperties("orc.compress"="NONE");-- 设置orc存储不使用压缩默认会使用zlib

ORC存储方式的压缩：

Key	Default	Notes
orc.compress	ZLIB	high level compression (one of NONE, ZLIB, SNAPPY)
orc.compress.size	262,144	number of bytes in each compression chunk
orc.stripe.size	268,435,456	number of bytes in each stripe
orc.row.index.stride	10,000	number of rows between index entries (must be >= 1000)
orc.create.index	true	whether to create row indexes
orc.bloom.filter.columns	“”	comma separated list of column names for which bloom filter should be created
orc.bloom.filter.fpp	0.05	false positive probability for bloom filter (must >0.0 and <1.0)

注意：所有关于ORCFile的参数都是在HQL语句的TBLPROPERTIES字段里面出现

2、上传数据

insert into table log_orc select * from log_text ;

3、查看大小

dfs -du -h /user/hive/warehouse/log_orc/;

ORC存储格式和Snappy压缩

1、建表

create table log_orc_snappy(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc
tblproperties("orc.compress"="SNAPPY");

2、导入数据

insert into log_orc_snappy select * from log_text;

3、查看大小

dfs -du -h /user/hive/warehouse/log_orc_snappy/ ;

总结

orc和parquet格式搭配压缩可以降低存储空间，且查询效率相近。

在实际的项目开发当中，hive表的数据存储格式一般选择：orc或parquet。压缩方式一般选择snappy，lzo。