现在我们有3个存储过程,分别是p1,p2,p3
如果按下列方式执行
begin
p1;
p2;
p3;
end;
它们是串行的。
我们可以使用DBMS_SCHEDULER包来间接实现并行执行,具体用法如下:
begin
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin p1; end;',
start_date => sysdate,
enabled => true,
comments => 'temporary job,will be delete soon after complete!',
auto_drop => true
);
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin p2; end;',
start_date => sysdate,
enabled => true,
comments => 'temporary job,will be delete soon after complete!',
auto_drop => true
);
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin p3; end;',
start_date => sysdate,
enabled => true,
comments => 'temporary job,will be delete soon after complete!',
auto_drop => true
);
end;
使用create_job来创建并立即执行一个job,执行完之后系统会自动删除。其中:
dbms_scheduler.generate_job_name 用来创建一个job_name,默认是JOB$_加上一个递增的数字,形如 JOB$_7983
start_time => sysdate 表示立即执行(需要同时将enabled设置为true)
enabled => true 只有这样才会立即执行
auto_drop => true 表示执行完自动删除
由于我们没有指定任何重复执行的参数,所以job创建后,它的SCHEDULE_TYPE=ONCE,而不是一般的CALENDAR。
可以通过
select * from user_scheduler_jobs;
查看。
在我的工作中遇到这么一个实际需求,伪代码如下:
begin
for rows in (select COL1 from tab) loop
业务逻辑处理;
end loop;
end;
处理逻辑部分比较简单,但是循环次数比较多,所以考虑将数据分片执行。
begin
for rows in (select col1
from (select mod(rownum, v_parallel_degree) + 1 part,
--part要加1,因为是取余
col1
from (select col1 from tab order by col2))
where part = v_part) loop
end loop;
end;
其中:
v_parallel_degree:分片的数量
v_part:用来取第x分片
将以上代码放到存储过程中,两个入参:v_parallel_degree,v_part
最后使用一个存储过程来调用
--***************************创建一个工具包用来创建job***************************
create or replace package pkg_utils is
procedure exec_pkg(v_pkg_name in varchar2);
--并行执行存储过程
procedure exec_proc_parallel(v_procedure_name in varchar2,
v_parallel_degree in int);
end pkg_utils;
/
create or replace package body pkg_utils is
--并行执行存储过程
procedure exec_proc_parallel(v_procedure_name in varchar2,
v_parallel_degree in int) is
begin
for i in 1 .. v_parallel_degree loop
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin ' || v_procedure_name || '(' ||
v_parallel_degree || ',' || i ||
'); end;',
start_date => sysdate,
enabled => true,
comments => v_procedure_name || '(' || i ||
' of ' || v_parallel_degree || ')',
auto_drop => true);
end loop;
end exec_proc_parallel;
begin
-- initialization
null;
end pkg_utils;
/
--***************************调用实例***************************
begin
pkg_utils.exec_proc_parallel('PROCEDURE_NAME', 16);
end;
/