0. 简介

之前尝试过使用plugin来实现功能的模块化.同时在ROS中,为了使核心的代码是只留下输入输出接口的，所以我们使用plugin来实现.so文件的封装以及动态调取.但是在近期接触后发现在RVIZ的插件开发中,其核心也是plugin插件性质,这里再开一篇文章来进行介绍.详细的配置可以在文章:ROS设置plugin插件中看到.

1. 内容介绍

rviz是ROS官方提供的一款3D可视化工具，几乎我们需要用到的所有机器人相关数据都可以在rviz中展现。当然由于机器人系统的需求不同，很多时候rviz中已有的一些功能仍然无法满足我们的需求，这个时候rviz的plugin机制就派上用场了。rviz可以使用插件机制来扩展丰富的功能，我们完全可以在rviz的基础上，打造属于我们自己的机器人人机界面。

在ros的编程中，ROS中的可视化工具绝大部分都是基于Qt进行开发的，rviz的plugin也不例外。而且古月老师也向我们展示了一个最基础的​​plugin的开发过程​​.

这里我们选取了一个最为常用的可发布多目标点任务的​​SLAM 建图导航插件​​.

ROS之RVIZ plugin_QT

2. 代码分析

plugin_description.xml

<library path="lib/libnavi_multi_goals_pub_rviz_plugin">
    <class name="navi_multi_goals_pub_rviz_plugin/MultiNaviGoalsPanel"
           type="navi_multi_goals_pub_rviz_plugin::MultiNaviGoalsPanel"
           base_class_type="rviz::Panel">
        <description>A panel widget allowing multi-goals navigation.</description>
    </class>
</library>

可以仔细看一下这个xml文件中的内容。

​​<library path="lib/libnavi_multi_goals_pub_rviz_plugin">​​ library标签写明了要输出的lib文件所在的相对路径；

​​<class></class>​​ class标签内容写明了插件的信息。

​​type​​：插件的完整类型，例如polygon_plugins::Triangle;

​​base_class_type​​：插件完整类型的父类，例如polygon_base::RegularPolygon;

​​description​​：描述插件是做什么的；

CMakeLists.txt

## BEGIN_TUTORIAL
## This CMakeLists.txt file for rviz_plugin_tutorials builds both the MultiNaviGoalsPanel tutorial and the ImuDisplay tutorial.
##
## First start with some standard catkin stuff.
cmake_minimum_required(VERSION 2.8.3)
project(navi_multi_goals_pub_rviz_plugin)
find_package(catkin REQUIRED COMPONENTS rviz geometry_msgs std_msgs actionlib_msgs)
catkin_package(CATKIN_DEPENDS message_runtime)
include_directories(${catkin_INCLUDE_DIRS})
link_directories(${catkin_LIBRARY_DIRS})

## This setting causes Qt's "MOC" generation to happen automatically.
set(CMAKE_AUTOMOC ON)

## This plugin includes Qt widgets, so we must include Qt.
## We'll use the version that rviz used so they are compatible.
if(rviz_QT_VERSION VERSION_LESS "5")
  message(STATUS "Using Qt4 based on the rviz_QT_VERSION: ${rviz_QT_VERSION}")
  find_package(Qt4 ${rviz_QT_VERSION} EXACT REQUIRED QtCore QtGui)
  ## pull in all required include dirs, define QT_LIBRARIES, etc.
  include(${QT_USE_FILE})
else()
  message(STATUS "Using Qt5 based on the rviz_QT_VERSION: ${rviz_QT_VERSION}")
  find_package(Qt5 ${rviz_QT_VERSION} EXACT REQUIRED Core Widgets)
  ## make target_link_libraries(${QT_LIBRARIES}) pull in all required dependencies
  set(QT_LIBRARIES Qt5::Widgets)
endif()
## I prefer the Qt signals and slots to avoid defining "emit", "slots",
## etc because they can conflict with boost signals, so define QT_NO_KEYWORDS here.
add_definitions(-DQT_NO_KEYWORDS)

## Here we specify which header files need to be run through "moc",
## Qt's meta-object compiler.


## Here we specify the list of source files, including the output of
## the previous command which is stored in ``${MOC_FILES}``.
set(SOURCE_FILES
  src/multi_navi_goal_panel.cpp
  ${MOC_FILES}
)

## An rviz plugin is just a shared library, so here we declare the
## library to be called ``${PROJECT_NAME}`` (which is
## "rviz_plugin_tutorials", or whatever your version of this project
## is called) and specify the list of source files we collected above
## in ``${SOURCE_FILES}``.
add_library(${PROJECT_NAME} ${SOURCE_FILES})

## Link the library with whatever Qt libraries have been defined by
## the ``find_package(Qt4 ...)`` line above, and with whatever libraries
## catkin has included.
##
## Although this puts "rviz_plugin_tutorials" (or whatever you have
## called the project) as the name of the library, cmake knows it is a
## library and names the actual file something like
## "librviz_plugin_tutorials.so", or whatever is appropriate for your
## particular OS.
target_link_libraries(${PROJECT_NAME} ${QT_LIBRARIES} ${catkin_LIBRARIES})
## END_TUTORIAL


## Install rules

install(TARGETS
  ${PROJECT_NAME}
  ARCHIVE DESTINATION ${CATKIN_PACKAGE_LIB_DESTINATION}
  LIBRARY DESTINATION ${CATKIN_PACKAGE_LIB_DESTINATION}
  RUNTIME DESTINATION ${CATKIN_PACKAGE_BIN_DESTINATION}
)

#可以考虑下面的使用install实现将插件放置到可执行文件或者库文件中
install(FILES 
  plugin_description.xml
  DESTINATION ${CATKIN_PACKAGE_SHARE_DESTINATION})
install(DIRECTORY icons/
        DESTINATION ${CATKIN_PACKAGE_SHARE_DESTINATION}/icons)

install(DIRECTORY media/
        DESTINATION ${CATKIN_PACKAGE_SHARE_DESTINATION}/media)

install具体可以参照​​《CMakeLists文件install的使用》​​进行设置，ROS当中的​​CATKIN_PACKAGE_SHARE_DESTINATION​​​可以参照​​下文​​。