汇编程序：转圈求和

原创

sxhelijian 2021-05-26 10:03:34 ©著作权

©著作权归作者所有：来自51CTO博客作者sxhelijian的原创作品，请联系作者获取转载授权，否则将追究法律责任

转圈求和

　　（1）写程序，对给出的8个数，将相邻的数求和（最后写第一个数与最后一个数的和），并把结果写在其后。在下面的示例中，求和的结果为3 5 7 9 11 13 15 9。

datasg segment
      dw 1, 2, 3, 4, 5, 6, 7, 8
      dw 0,0,0,0,0,0,0,0
datasg ends

提示1：相邻的两数，若前一数用[si]指示，相邻的后面一数则为[si+2]
提示2：前7个和数可以用统一的规则做出，最后一个和数，呃，转圈回去了，不妨特殊处理。

[参考解答]

assume cs:codesg,ds:datasg
datasg segment
      dw 1, 2, 3, 4, 5, 6, 7, 8
      dw 0,0,0,0,0,0,0,0
datasg ends
codesg segment
start: mov ax, datasg
       mov ds, ax
       mov si, 0      ;源数据地址
       mov di, 16     ;结果写入地址
       mov cx, 7      ;先处理前7轮
    s: mov ax, [si]   ;相邻数中第1个
       add ax, [si+2] ;加上相邻的后一个数
       mov [di], ax   ;写入结果
       add si, 2
       add di, 2
       loop s

       mov ax, [si]   ;最后一个数
       add ax, ds:[0] ;加上第一个数，这儿的ds:不可省去，原因找课程前面讲过的内容
       mov [di], ax   ;作为最后一个和

       mov ax,4c00h
       int 21h
codesg ends
end start

　　（2）若要求将结果写在提供源数据的位置上，而不是在随后的空间中呢？
[参考解答]

assume cs:codesg,ds:datasg
datasg segment
      dw 1, 2, 3, 4, 5, 6, 7, 8
datasg ends
codesg segment
start: mov ax, datasg
       mov ds, ax
       mov si, 0      ;源数据地址
       mov cx, 7      ;先处理前7轮
       mov dx, [si]   ;关键：把第一个数暂存起来，因为这个位置上，很快要被写入求和结果了
    s: mov ax, [si]   ;相邻数中第1个
       add ax, [si+2] ;加上相邻的后一个数
       mov [si], ax   ;写入结果
       add si, 2
       loop s

       mov ax, [si]   ;最后一个数
       add ax, dx     ;加上提前暂存的第一个数
       mov [si], ax   ;存入最后一个和

       mov ax,4c00h
       int 21h
codesg ends
end start