H3C R4900 G3出厂设置HDM专用口默认IP：192.168.1.2，默认用户名：admin，默认密码：Password@_ 服务器安装以后需要根据实际情况修改HDM IP。 如果一台一台的修改会比较繁琐，现场交付时大多使用Windows笔记本电脑，使用批处理制作了快速配置脚本。将笔记本电脑的网口和HDM 专用口直连就可以进行快速的配置。 可进行的配置包括 1、根据实际需求的HDM用户和密码 2、修改出厂默认用户admin的密码 3、根据服务器序列号配置HDM IP

使用前准备： 1、需要将序列号和对应的HDM IP写入文件 list.csv，与脚本放在同一个文件夹中 例：

序列号,HDM IP
210XXXXXXXXXXXXXXXX1,192.168.100.1
210XXXXXXXXXXXXXXXX2,192.168.101.2
210XXXXXXXXXXXXXXXX3,192.168.103.3

2、脚本需要调用ipmitool for windows和awk for Windows，放在脚本文件夹的bin文件夹中。 例：

│  H3C_R4900_G3_HDM_tool.bat
│  list.csv
│
└─bin
        awk.exe
        cygcrypto-0.9.8.dll
        cygwin1.dll
        ipmitool.exe

3、需要在脚本开始处为创建用户的用户名和密码变量进行赋值，同时会将HDM默认的密码修改为该密码。

set password=
set username=

4、脚本中的默认网关为X.X.X.254，子网掩码为255.255.255.0。可根据实际情况修改。 5、执行脚本前需要在笔记本的网卡中添加多个IP，保证可以同时连通192.168.1.2和修改后HMD的IP

H3C_R4900_G3_HDM_tool.bat

@echo off
title H3C R4900 G3服务器HMD初始化配置工具
cd /d %~dp0
set password=
set username=
if "%password%"=="" echo password为空&goto error3
if "%username%"=="" echo username为空&goto error3
IF not exist list.csv echo list.csv 不存在&goto error2
IF not exist bin\awk.exe echo bin\awk.exe 不存在&goto error2
IF not exist bin\cygcrypto-0.9.8.dll echo bin\cygcrypto-0.9.8.dll 不存在&goto error2
IF not exist bin\cygwin1.dll echo bin\cygwin1.dll 不存在&goto error2
IF not exist bin\ipmitool.exe echo bin\ipmitool.exe 不存在&goto error2
set num=1
start ping 192.168.1.2 -t
:begin
cls
bin\ipmitool.exe -I lanplus -U admin -P Password@_ -H 192.168.1.2 fru|findstr /c:"Chassis Serial"|bin\awk "{print $4}">sn.txt
set /p sn=<sn.txt
findstr %sn% list.csv>nul
IF ERRORLEVEL 1 goto error1
findstr %sn% list.csv|bin\awk -F, "{print $2}">ip.txt
set /p ip=<ip.txt
for /f "tokens=1,2,3,4 delims=." %%i in ("%ip%") do (set gw=%%i.%%j.%%k.254)
bin\ipmitool -U admin -P Password@_ -I lanplus -H 192.168.1.2 user set name 3 %username%>nul
bin\ipmitool -U admin -P Password@_ -I lanplus -H 192.168.1.2 user set password 3 %password%>nul
bin\ipmitool -U admin -P Password@_ -I lanplus -H 192.168.1.2 user enable 3>nul
bin\ipmitool -U admin -P Password@_ -I lanplus -H 192.168.1.2 user priv 3 04 1>nul
echo 已创建用户%username%
echo.
bin\ipmitool -U admin -P Password@_ -I lanplus -H 192.168.1.2 user set password 1 %password%>nul
echo 已修改默认用户密码
echo.
bin\ipmitool -U admin -P %password% -I lanplus -H 192.168.1.2 lan set 8 defgw ipaddr %gw%>nul
bin\ipmitool -U admin -P %password% -I lanplus -H 192.168.1.2 lan set 8 netmask 255.255.255.0>nul
bin\ipmitool -U admin -P %password% -I lanplus -H 192.168.1.2 lan set 8 ipaddr %ip%>nul
echo 已将HDM IP修改为%ip%，等待IP配置生效。
echo.
ping -n 10 127.0.0.1>nul
start ping %ip%
echo %sn%>>done.txt
echo 已执行%num%台
echo.
set /a num=num+1
del ip.txt sn.txt
apr -d 192.168.1.2
echo 请确认IP %ip%是否ping通。如果IP不通，请手工排查。
echo.
echo 按任意键继续执行，退出请直接关闭窗口。
echo.
echo 继续执行前请确认192.168.1.2可以ping通。如果不通可尝使用管理员权限执行命令 apr -d 192.168.1.2
pause
goto begin

:error1
echo 当前服务器序列号%sn%，未在list.csv文件中查找到，请确认设备信息。
echo 按任意键退出
del sn.txt
pause
exit

:error2
echo 缺少必要文件，请确认工具完整性
pause
exit

:error3
echo 未设置username或passowrd变量，请编辑脚本文件设置用户名和密码。注意特殊字符在批处理中的转义
pause
exit

执行完成的服务器序列号会写入done.txt。 脚本中添加了清除ARP的操作，需要以管理员权限运行脚本 G5 产品 1 表示专用口，8 表示共享口。G3产品 1 共享，8 专用口

配置完一台服务器后切换到另一台服务器时192.168.1.2可能会不通，确认物理链路畅通后。可尝试使用管理员权限执行命令 arp -d 192.168.1.2