目录
显变量模型语法
潜变量模型语法
Mplus语法
中介效应检验
Mplus语句
结果解读
1. 模型拟合
2. 路径系数值及显著性
3. 中介效应值及显著性
其他
除了简单中介模型，具有两个中介变量的、常见的模型之一是链式中介模型。在该模型中，两个中介变量在时间上存在先后顺序的关系。如下图所示。中介变量M1在前，M2在后。
显变量模型语法
以上图为例，显变量模型语法为：
TITLE: MEDIATION MODEL;
DATA: FILE IS 12.dat; ! 数据来源
VARIABLE: NAME ARE X M1 M2 Y; ! 变量名称
MISSING=ALL(99); ! 定义缺失值
USEVARIABLE ARE X M1 M2 Y; ! 使用的变量
ANALYSIS: ESTIMATOR=MLR; ! 估计方法，根据自己的数据特点，可选择其他方法，例如ML
MODEL: Y M1 M2 ON X; ! X指向M1、M2、Y的路径
Y ON M1 M2; ! M1、M2指向Y的路径
M2 ON M1; ! M1指向M2的路径
OUTPUT: SAMPSTAT STDYX MOD CINTERVAL; ! 输出样本统计量、标准化值、修正系数、置信区间
潜变量模型语法
Mplus语法
TITLE: MEDIATION MODEL;
DATA: FILE IS 12.dat; ! 数据来源
VARIABLE: NAME ARE X1-X4 A1-A4 B1-B4 Y1-Y4; ! 变量名称
MISSING=ALL(99); ! 定义缺失值
USEVARIABLE ARE X1-X4 A1-A4 B1-B4 Y1-Y4; ! 使用的变量
ANALYSIS: ESTIMATOR=MLR; ! 估计方法，根据自己的数据特点，可选择其他方法，例如ML
MODEL: A BY X1-X4;
B BY A1-A4;
C BY B1-B4;
D BY Y1-Y4; ! 通过BY，创建四个潜变量
D B C ON A; ! A指向B、C、D的路径
D ON B C; ! B、C指向D的路径
C ON B; ! B指向C的路径
OUTPUT: SAMPSTAT STDYX MOD CINTERVAL; ! 输出样本统计量、标准化值、修正系数、置信区间
中介效应检验
显变量链式中介模型
以显变量模型为例，采用Bootstrap进行中介效应检验的语法为：
潜变量模型同理，在ANALYSIS中采用BOOTSTRAP法。
Mplus语句
TITLE: MEDIATION MODEL;
DATA: FILE IS 12.dat; ! 数据来源
VARIABLE: NAME ARE X M1 M2 Y; ! 变量名称
MISSING=ALL(99); ! 定义缺失值
USEVARIABLE ARE X M1 M2 Y; ! 使用的变量
ANALYSIS: BOOTSTRAP=2000; ! 采用Bootstrap法进行中介效应检验，抽样次数1000/2000/5000，有文献依据即可
MODEL: Y ON X (cdash); ! X到Y的路径命名为c’
Y ON M1 (b1); ! M1到Y的路径命名为b1
Y ON M2 (b2); ! M2到Y的路径命名为b2
M1 ON X (a1); ! X到M1的路径命名为a1
M2 ON X (a2); ! X到M2的路径命名为a2
M2 ON M1(d); ! M1到M2的路径命名为d
MODEL CONSTRAINT: NEW(a1b1 a2b2 a1db2 TOTALIND TOTAL); ! 需要生成的新系数
a1b1 = a1*b1; ! X通过中介变量M1对Y的间接效应
a2b2 = a2*b2; ! X通过中介变量M2对Y的间接效应
a1db2 = a1*d*b2; ! X通过M1、M2对Y的间接效应
TOTALIND = a1*b1 + a2*b2 + a1*d*b2; ! X对Y的总间接效应
TOTAL = a1*b1 + a2*b2 +a1*d*b2 + cdash; ! X对Y的总效应=间接+直接
OUTPUT: SAMPSTAT STDYX MOD CINTERVAL; ! 输出样本统计量、标准化值、修正系数、置信区间
结果解读
以显变量模型为例，关注三方面的结果。
1. 模型拟合
显变量模型为饱和模型，无需看模型拟合。
潜变量模型可根据文献选取模型拟合指标及标准，对模型的拟合情况进行判断。
显变量模型拟合
2. 路径系数值及显著性
显变量模型非标准化结果与标准化结果
由下图可知：显变量模型中，所有路径均显著。
显变量模型非标准化结果
显变量模型标准化结果
显变量模型图
3. 中介效应值及显著性
由下图可知：中介效应显著。
中介效应检验结果
其他
1. 潜变量指标太多的话，可以通过项目打包的方式，简化模型和提高模型的拟合度。
2. Bootstrap和MLR估计方法不能同时使用。
