BIOS和BMC通信 bios bmc

一、实模式下的内存布局

一直到第4章之前程序都是运行在实模式下，所以需要先了解实模式下的内存布局。实模式下只会使用cpu的20条地址线，所以只能访问和使用到1MB的地址空间。用一张图表示

一、第一棒 BIOS

主机通电后第一个运行的软件就是BIOS，由主板加载
BIOS全称Base Input & Output System，即基本输入输出系统。
bios功能：检查内存、显卡等外设信息，初始化硬件，在0x000~0x3ff建立数据结构，中断向量表IVT并填写中断例程。最后一步校验启动盘中位于0盘0道1扇区的内容（MBR）并加载到0x7c00处。检查完毕后跳转到0x7c00（MBR处）。
启动bochs

./bochs -f bochsrc.disk

第一行代码为：jmp far f000:e05b bios的真正地址

三、第二棒MBR

1.汇编中的$和$$

$和$$是nasm的保留字。
$：表示代码的当前行
$$：表示本section的地址
在后面计算需要填充多少大小才能到512字节时有奇效

2.MBR

MBR在0x7c00，大小为512字节且最后两个字节是0x55 0xaa。

;主引导程序 
;------------------------------------------------------------
SECTION MBR vstart=0x7c00         
   mov ax,cs      
   mov ds,ax
   mov es,ax
   mov ss,ax
   mov fs,ax
   mov sp,0x7c00

; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06	   功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
   mov     ax, 0x600
   mov     bx, 0x700
   mov     cx, 0           ; 左上角: (0, 0)
   mov     dx, 0x184f	   ; 右下角: (80,25),
			   ; VGA文本模式中,一行只能容纳80个字符,共25行。
			   ; 下标从0开始,所以0x18=24,0x4f=79
   int     0x10            ; int 0x10

;;;;;;;;;    下面这三行代码是获取光标位置    ;;;;;;;;;
;.get_cursor获取当前光标位置,在光标位置处打印字符.
   mov ah, 3		; 输入: 3号子功能是获取光标位置,需要存入ah寄存器
   mov bh, 0		; bh寄存器存储的是待获取光标的页号

   int 0x10		; 输出: ch=光标开始行,cl=光标结束行
			; dh=光标所在行号,dl=光标所在列号

;;;;;;;;;    获取光标位置结束    ;;;;;;;;;;;;;;;;

;;;;;;;;;     打印字符串    ;;;;;;;;;;;
   ;还是用10h中断,不过这次是调用13号子功能打印字符串
   mov ax, message 
   mov bp, ax		; es:bp 为串首地址, es此时同cs一致，
			; 开头时已经为sreg初始化

   ; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
   mov cx, 5		; cx 为串长度,不包括结束符0的字符个数
   mov ax, 0x1301	; 子功能号13是显示字符及属性,要存入ah寄存器,
			; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
   mov bx, 0x2		; bh存储要显示的页号,此处是第0页,
			; bl中是字符属性, 属性黑底绿字(bl = 02h)
   int 0x10		; 执行BIOS 0x10 号中断
;;;;;;;;;      打字字符串结束	 ;;;;;;;;;;;;;;;

   jmp $		; 使程序悬停在此

   message db "1 MBR"
   times 510-($-$$) db 0
   db 0x55,0xaa

生成mbr.bin

nasm -o mbr.bin mbr.S

将mbr.bin写入到hd60M.img中

dd if=mbr.bin of=hd60M.img bs=512 count=1 conv=notrunc

参数解析

• if=File：input File的缩写，需要读入的文件
• of=File：output File的缩写，被写入的文件
• bs=BYTES：指定块的大小，dd是怡块为单位进行IO操作的
• count=BLOCKS：块的数量
• seek=BLOCKS：需要跳过的块数量
• conv=CONVS：用指定的参数转换文件，notrunc表示不截短文件

运行bochs

bochs -f bochsrc.disk

出现字符"1 MBR"

总结

1. 了解1MB的地址空间布局
2. 了解BIOS的功能：自检，进行一些初始化（中断向量表等），加载MBR到0x7c00，最后跳转执行
3. MBR在0x7c00处，大小为512字节，且结尾两个字节为0x55，0xaa