For命令详解
基本格式：
FOR 参数 %%变量名 IN (相关文件或命令) DO 执行的命令
参数:
4个参数 /d /l /r /f 他们的作用我在下面用例子解释
%%变量名 :
这个变量名可以是小写a-z或者大写A-Z,他们区分大小写哦，FOR会把每个读取到的值给他!
执行的命令:
对每个变量的值要执行什么操作就写在这.
1、/d 目录
描述：仅为目录 执行制定操作，而忽略文件
说明：如果 Set 包含通配符（* 和 ?），将对与 Set 相匹配的每个目录（而不是指定目录中的文件组）执行指定的 Command。他主要用于目录搜索,不会搜索文件。
例子1：
@echo off
for /d %%i in (*) do @echo %%i
pause
把他保存放在C盘根目录执行,就会把C盘目录下的全部目录名字打印出来,而文件名字一个也不显示!
例子2：
比如我们要把当前路径下文件夹的名字只有1-3个字母的显示出来。
@echo off
for /d %%i in (???) do @echo %%i
pause
这样的话如果你当前目录下有目录名字只有1-3个字母的,就会显示出来,没有就不显示了
例子3：
@echo off
for /d %%i in (window?) do @echo %%i
pause
保存到C盘下执行,会显示什么呢?自己看吧!
2、/R递归
描述：进入根目录树 [Drive:]Path，在树的每个目录中执行 for 语句。如果在 /R 后没有指定目录，则认为是当前目录。如果 Set 只是一个句点 (.)，则只枚举目录树。
例子1:
把当前或者你指定路径下的文件名字全部读取,注意是文件名字
@echo off
for /r c:\ %%i in (*.exe) do @echo %%i
pause
把这个BAT保存到D盘随便哪里然后执行,我会就会看到,他把C盘根目录,和每个目录的子目录下面全部的EXE文件都列出来了!!!!
例子2：
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
参数不一样了吧!这个命令前面没加那个C:\也就是搜索路径,这样他就会以当前目录为搜索路径,比如你这个BAT你把他防灾d:\test目录下执行,那么他就会把D:\test目录和他下面的子目录的全部EXE文件列出来!!!
3、/L迭代数值范围
描述：使用迭代变量设置起始值 (Start#)，然后逐步执行一组范围的值，直到该值超过所设置的终止值 (End#)。/L 将通过对 Start# 与 End# 进行比较来执行迭代变量。如果 Start# 小于 End#，就会执行该命令。如果迭代变量超过 End#，则命令解释程序退出此循环。还可以使用负的 Step# 以递减数值的方式逐步执行此范围内的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 则生成序列 (5 4 3 2 1)。
语法：
for /L %% Variable in (Start#,Step#,End#) do Command
例子1：
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存执行看效果,他会打印从1 2 3 4 5 这样5个数字。(1,1,5)这个参数也就是表示从1开始每次加1直到5终止!
例子2：：
@echo off
for /l %%i in (1,1,5) do start cmd
pause
执行后是不是吓了一跳,怎么多了5个CMD窗口,呵呵!如果把那个 (1,1,5)改成 (1,1,65535)会有什么结果,我先告诉大家,会打开65535个CMD窗口....这么多你不死机算你强!
当然我们也可以把那个start cmd改成md %%i 这样就会建立指定个目录了，名字为1-65535
4、/f迭代及文件解析
描述：
使用文件解析来处理命令输出、字符串及文件内容。使用迭代变量定义要检查的内容或字符串，并使用各种 ParsingKeywords 选项进一步修改解析方式。使用 ParsingKeywords 令牌选项指定哪些令牌应该作为迭代变量传递。
语法：
for /F "ParsingKeywords" %% Variable in (FileNameSet) do Command
for /F "ParsingKeywords" %% Variable in (FileNameSet) do Command
注意：在没有使用令牌选项时，/F 将只检查第一个令牌。
说明：
文件解析过程包括读取输出、字符串或文件内容，将其分成独立的文本行以及再将每行解析成零个或更多个令牌。然后通过设置为令牌的迭代变量值，调用 for 循环。默认情况下，/F 传递每个文件每一行的第一个空白分隔符号。跳过空行。
参数：
ParsingKeywords
他表示4个参数
eol=c 指一个行注释字符的结尾(就一个)
skip=n 指在文件开始时忽略的行数。
delims=xxx 指分隔符集。这个替换了空格和跳格键的默认分隔符集。
tokens=x,y,m-n指每行的哪一个符号被传递到每个迭代 的 for 本身。这会导致额外变量名称的分配。m-n格式为一个范围。通过 nth 符号指定 mth。如果符号字符串中的最后一个字符星号，那么额外的变量将在最后一个符号解析之后分配并接受行的保留文本。
usebackq 指定新语法已在下类情况中使用:
在作为命令执行一个后引号的字符串并且一个单引号字符为文字字符串命令并允许在 filenameset中使用双引号扩起文件名称。
usebackq这个参数不用理解了,系统默认会给我们加上!
例子1：
为了能使用这个例子,我们先新建一个文本文件,在里面打上这些内容保存为test.txt:
;郁闷啊!
您好! 欢迎来到, 非常批处理
我们的网站 bbs.verybat.org
完毕!
@echo off
FOR /F "eol=; tokens=1 delims= " %%i in (test.txt) do @echo %%i
pause
我们把这个BAT保存到和你的test.txt相同的目录下面然后执行
我们会看到屏幕上会显示：
您好!
我们的网站
完毕!
为什么会这样?我来解释
这个命令会读取在当前目录下名为test.txt文件中的内容,将每一行的内容赋值给变量%%i,忽略掉以;号开头的行,并且以空格做为分隔符号,打印每行以空格做分隔符号的第一列
结果就是这样了!!
例子2：
@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause
这样你本机全部帐号名字就出来了把扩号内的内容用两个单引号引起来就表示那个当命令执行,FOR会返回命令的每行结果,加那个"delims=" 是为了让我空格的行能整行显示出来,不加就只显示空格左边一列!
