bat 批量启动java 批量运行bat

转载

mob6454cc78b025 2024-01-17 09:58:54

文章标签 bat 批量启动java 批处理批处理文件分隔符 文章分类 Java 后端开发

一、为什么要学习？

1、写作背景

　　在windows条下有时候需要批量执行一些内容，比如开机后常用软件的批量打开等，使用bat能够方便快捷的解决类似问题。所以，今天下决心来了解下bat脚本语法及逻辑，希望能用到更多的场景中去，目的是：能用工具解决的，尽量不用人工处理。　　

简单的说，批处理的作用就是自动的连续执行多条命令。

2、这里先讲一个最简单的应用：在启动wps软件时，每次都必须执行（>前面内容表示DOS提示符）：

C:\>cd wps
C:\WPS>spdos
C:\WPS>py
C:\WPS>wbx
C:\WPS>wps
如果每次用WPS之前都这样执行一遍，您是不是觉得很麻烦呢？
好了，用批处理，就可以实现将这些麻烦的操作简单化，首先我们编写一个runwps.bat批处理文件，内容如下：
@echo off
c:
cd\wps
spdos
py
wbx
wps
cd\
以后，我们每次进入wps，只需要运行runwps这个批处理文件即可。

二、bat简介

　　bat （批处理文件类型）：批处理文件，在DOS和Windows（任意）系统中使用，.bat文件是可执行文件，由一系列命令构成，其中可以包含对其他程序的调用。

　　这个文件的每一行都是一条DOS命令（大部分时候就好像我们在DOS提示符下执行的命令行一样），你可以使用DOS下的Edit或者Windows的记事本(notepad)等任何文本文件编辑工具创建和修改批处理文件。

　　批处理(Batch)，也称为批处理脚本。顾名思义，批处理就是对某对象进行批量的处理，通常被认为是一种简化的脚本语言，它应用于DOS和Windows系统中。批处理文件的扩展名为bat 或cmd。目前比较常见的批处理包含两类：DOS批处理和PS批处理。PS批处理是基于强大的图片编辑软件Photoshop的，用来批量处理图片的脚本；而DOS批处理则是基于DOS命令的，用来自动地批量地执行DOS命令以实现特定操作的脚本。更复杂的情况，需要使用if、for、goto等命令控制程式的运行过程，如同C、Basic等高级语言一样。如果需要实现更复杂的应用，利用外部程式是必要的，这包括系统本身提供的外部命令和第三方提供的工具或者软件。批处理程序虽然是在命令行环境中运行，但不仅仅能使用命令行软件，任何当前系统下可运行的程序都可以放在批处理文件中运行。

三、变量

1、变量的类型

　　批处理中的变量基本上是万能的,可以储存各种各样的数据,不过用来计算时你会发现变量类型转为了int,数值的极端范围为[-2147483648，2147483647],如果不拿来计算的话,似乎数万位也是可以的

2、变量的命名

　　批处理的变量命名没有什么限制，不过建议命名还是遵守标准的命名方法,不然像这样的代码是很蛋疼的。
@Echo Off
Set IF=Set
%IF% lF=Goto
:IF
IF %IF%==IF %lF% IF
　　正是因为变量的名称是可以自由调配的：数字、字母、甚至汉字都可以变成变量名样。

3、变量的扩展（使用变量）

　　扩展,你可以理解为显示出这个的值,如果你想要使用这个变量的值一般情况下都要扩展

　　扩展方式:%变量%或!变量!

　　其中!变量!是延迟扩展,需要加上SetLocal EnableDelayedExpansion语句才能够实现,延迟扩展对于新手来说是一个很难理解的东西,就这么说吧,当你的变量在一个语句的内部受到了改变,而在这个改变之后又要输出,那么你必须要延迟扩展,这个牵扯到了奇奇怪怪的预处理机制,不详解了。

　　用连接符号连起来的语句,if,for和它们后面括号内的内容都是属于一个语句

例:

@echo off
set num=10
set num=100 & echo %num%
echo %num%
echo 虽然已经将num的值更改为100,但由于没有延迟扩展,所以值仍为10,不过在下一个语句num的值就改变了
pause>nul
例:
@echo off
SetLocal EnableDelayedExpansion
set num=10
set num=100&echo !num!
echo 现在两个num的值一样了
echo %num%
pause>nul
变量在扩展过程中还可以做一点手脚
例:
set str=1234567890
echo %str:~0,5%
echo %str:~1,5%
echo %str:~-5%
　　echo %str:~5,-2%
echo %str:7890=54321%
pause>nul
很神奇吧?这就是对字符串的处理，这个是批处理的特性，叫“变量延迟”

四、关于参数

参数在批处理的表达是%0,%1,%2....%9 ，以及全部参数%*（不包括%0）
%0的初始量是批处理本身路径，类似%~f0
一般你只能取前九个参数，除非你使用%*
shift命令允许你获取后面的参数
格式：shift [/n]
n为1~8的数

shift 会使%0变成%1，%1变成%2……%9变成原来的第10个参数（不推荐）
一般使用shift /1，将会从%1开始替换，保留原%0
注意：call标签时参数也是可用的，而且当返回时参数将变回原来的
例子：
@echo off

call :标签 arg1 arg2
echo %1
::会显示回显已打开
echo %2
exit
:标签
echo %1
::这时会显示arg1
echo %2
::这时会显示arg2
exit /b

五、常用命令

1、ECHO，显示及关闭回显，输出信息及空行。

@echo on ：打开回显，显示执行脚本的命令内容。

@echo off ：关闭回显

echo message：输出消息message

echo：后面不接内容，表示输出空行。

2、PAUSE，暂停批处理程序，并显示以下消息:请按任意键继续. . .

此命令不再做描述，如标题所示。

3、CLS清除屏幕。

此命令不再做描述，如标题所示。

4、REM

在批处理文件或 CONFIG.SYS 里加上注解或说明。

REM [comment]
这个命令同样没什么好说的,用法就是rem 注释
PS:其实可以用"::"代替"REM",可以提高执行速度,不过REM的兼容性更好,我还是建议大家用rem注释

5、SET

　　1）给变量赋值(撤销)

例1:
@echo off
set str=My name is Xiao
rem 批处理脚本中用%或！来表示扩展
echo %str%
rem pause默认输出信息为"请按任意键继续"，也可以自定义输出，例如pause>nul
pause>nul

例2.
@echo off
set str=ABCDEFGHIJKLMN
echo %str%
set str=
rem 还记得加";"，这里的分号";"必须跟echo不能有空格，作用是打开前面已经关闭的回显，并且输出变量；否则不输出变量且输出提示“ECHO 处于关闭状态。”
echo;%str%
pause>nul

上面的例子中,一个是给变量赋值,一个是撤销变量的值

　　2）等待用户输入数据(开关/P)

例:　　
@echo off
set /p name=请输入你的姓名:
set /p age=请输入你的年龄(纯数字):
echo 所以,%name%今年%age%岁咯?
pause>nul

　　3）计算(开关/A)

set /a支持多行表达式并列,比如set /a num1=1+1,num2=1+2,num3=1+3
并且set /a不需要扩展变量,比如set /a num=%num2%+%num3%与set /a num=num2+num3等价

例1:
@echo off
set /a num=(12*2)+(13*4)
echo (12x2)+(13x4)=%num%
pause>nul
例2:
@echo off
set /p num=请输入一个数字(不要超过2147483647):
REM 批处理能处理的数字不能超过32位(二进制)
set /a num*=2
echo 这个数字的两倍是%num%
pause>nul
附:Set /a num*=2与set /a num=num*2等价

() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
- 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= - 赋值
&= ^= |= <<= >>=
, - 表达式分隔符

　　4）显示当前已定义变量

例:
@set
@pause>nul
是不是很简单?其实它还有更高级的用法呢

@set a
@pause>nul
@set s
@pause>nul
你们发现什么了吗??它的用法就是这些,不用多说了

6、IF

　　1）IF的第一种用法,比较字符串

例:
set /p PW=请输入密码:
if %PW%==bat (
echo YES!　
) ELSE (
Rem [else] 为可选参数,表示否则,即如果变量PW等于bat则输出YES!否则输出NO!　
echo NO!　
)
pause>nul
通过set /p和if可以实现一个简单的密码判断,当然这个密码判断可以很轻易地被破解,仔细动脑筋想一想,该怎么破解呢.
不过这个密码判断尚有不足之处,假如我们什么都不输入直接回车,便会提示错误,那该怎么办呢?很简单,只要加上双引号(其它的符号也行)就行了=>if "%PW%"=="bat"

　　2）IF的第二种用法,比较数字

例:
set /p num1=请第一个输入数字:
set /p num2=请第二个输入数字:
if not %num1% LSS %num2% (
rem lss表示小于　　
rem [not]为可选参数,表示非,即如果变量num1不小于变量num2就输出第一个数字大,否则输出第二个数字大
echo 第一个数字大
) ELSE (
echo 第二个数字大　　
)
pause>nul

这段代码可以实现一个简单的判断,不过尚有不足之处-----如果这两个数字相等呢,这就要请出我们的else if啦(当然你也可以用几个if来判断)
set /p num1=请第一个输入数字:
set /p num2=请第二个输入数字:
if "%num1%" gtr "%num2%" (
echo 第一个数字大
) ELSE if "%num1%" EQU "%num2%" (
echo 一样大　　
) ELSE (
echo 第二个数字大　
)
pause>nul

------比较运算符-----
EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于

　　3）IF的第三种用法,检测文件(夹)是否存在

例:
@echo off
if exist C:\windows (
echo 你的C盘有windows文件(夹^)
　　
) else (
echo 你的C盘没有windows文件(夹^)
　　
)
pause>nul
"^"为转义符号,在特殊符号一节再作讲解

　4）IF的第四种用法,检测变量是否被定义

例:
@echo off
set var=aiwozhonghua
if defined var (
echo 变量var已被定义,它的值为%var%　　
) else (
echo 变量var没有被定义　　
)
pause>nul
去掉第一行的set看看执行结果有什么不同,你明白它的用法了吗?

　　5）IF的第五种用法,判断返回值(ERRORLEVEL)

要判断返回值,首先要理解返回值是个什么概念,批处理中的返回值一般表示了上个命令的执行结果(成功/失败/等)
每个命令执行完毕后返回值都会做相应的更改,一般返回值为0表示成功,1表示失败,有一些第三方的返回值比较特殊(如Choice.exe,Tmos.exe,Cmos.exe),在这里就不讲解了
例:
@echo off
echo;>>%systemroot%\test.txt
if errorlevel 0 ( echo 写入成功! ) else echo 写入失败
pause>nul
这段代码尝试向%systemroot%\system32\写入数据,如果权限不够或杀毒软件拦截就会写入失败,这时就会显示"写入失败".不知道%systemroot%表示了什么?单独键入set自己仔细看一下结果.
　　
不过看到后面你会发现这段代码还有更简便的写法
注:用 if errorlevel判断返回值时要将返回值从大到小排列
例:
@echo off
choice /C:ABC /n "A/B/C"
if errorlevel 3 echo You choose the C
if errorlevel 2 echo You choose the B
if errorlevel 1 echo You choose the A
pause>nul
GOTO
将 cmd.exe 导向到批处理程序中带标签的行。
GOTO label
label 指定批处理程序中用作标签的文字字符串。

　　6）goto及lable

标签必须单独一行，并且以冒号打头。

如果命令扩展名被启用，GOTO 会如下改变:
GOTO 命令现在接受目标标签 :EOF，这个标签将控制转移到当前批脚本文件的结尾。不定义就退出批脚本文件，这是一个容易的办法。有关能使该功能有用的 CALL 命令的扩展名描述，请键入CALL /?。label是什么?这可不是命令label,它指的是标签,标签是啥?见例子。

例:
@echo off
set /p pw=请输入密码:
if "%pw%"=="bathome" goto yes
goto :eof
rem 未定义的:eof会退出脚本文件
:yes
echo 密码正确!
pause>nul

这是一个更加完整的密码判断,仔细阅读并执行这行代码,现在你知道标签是什么了吗,没错,那个:yes就是标签了!

标签的格式
:标签名

关掉回显以后你有没有发现什么?没错,标签所在的那一行没有被执行,这就是为什么::比rem更快的原因了,但是标签不能被使用在一个语句的内部,主要就是被括号括起来的语句(是的,被括号括起来的语句被看作一个整体),因此::的兼容性没有rem那么好
附:"::"其实就是不规范的标签名...

7、FOR

　　1）FOR

对一组文件中的每一个文件执行某个特定命令。
FOR%variableIN (set) DO command [command-parameters]
%variable 指定一个单一字母可替换的参数。
(set) 指定一个或一组文件。可以使用通配符。
command 指定对每个文件执行的命令。
command-parameters
为特定命令指定参数或命令行开关。
例:

@echo off
E:
cd 工作\003 脚本命令
for %%i in (*.sql) do echo %%i
pause>nul

这段代码会显示当前文件夹下所有的sql文件

@echo off
for %%i in (菜芽小公公) do echo %%i
pause>nul
　　这段代码会显示
菜
芽
小
公
公
注:%%i为for输出专用变量格式,其中i可以是a/A/0-z/Z/9和一些符号什么的(如! # 不过不建议使用),在cmd中只能用一个%

　　2）FOR /L

FOR /L %variable IN (start,step,end) DO command [command-parameters]
该集表示以增量形式从开始到结束的一个数字序列。

因此，(1,1,5) 将产生序列 1 2 3 4 5，(5,-1,1) 将产生
序列 (5 4 3 2 1)。
例:
@echo off
for /L %%a in (1 2 1000) do echo %%a
　　pause>nul
输出1到1000之间的整数，间隔为2.

　　3）FOR /R

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
检查以 [drive:]path 为根的目录树，指向每个目录中的。
FOR 语句。如果在 /R 后没有指定目录，则使用当前目录。

如果集仅为一个单点(.)字符，则枚举该目录树。

例:

@echo off
for /r F:\Store\工作 %%i in (*) do echo %%i
pause>nul

枚举显示F:\Store\工作目录下的所有目录及文件夹，包括子文件夹里的。

　　4）FOR /D

FOR /D %variable IN (set) DO command [command-parameters]
如果集中包含通配符，则指定与目录名匹配，而不与文件名匹配。

　　5、FOR /F

for /f是一个非(丧)常(心)复(病)杂(狂)的命令...
让我们从它的第一个用法来讲:
FOR /F ["options"] %variable IN (file-set) DO command [command-parame
例:
@echo off
echo 1,1 2,1 3,1 4,1>>test.txt
echo A1,2 2,2 3,2 4,2>>test.txt
echo 1,3 2,3 3,3 4,3>>test.txt
echo A1,4 2,4 3,4 4,4>>test.txt
rem 以上代码在当前文件夹下生成了一个test.txt,打开看看?
For /F %%i In (test.txt) Do Echo %%i
pause>nul
For /F "tokens=2" %%i In (test.txt) Do Echo %%i
pause>nul
For /F "tokens=3" %%i In (test.txt) Do Echo %%i
pause>nul
For /F "tokens=4" %%i In (test.txt) Do Echo %%i
pause>nul
我想执行完这个bat,再分析一下结果和代码,聪明的你一定了解了tokens的用处

for /f 默认以空格为分隔符,将每一行分割为几个元素,而tokens就表示取第几个元素.但假如我们要取的不是一个元素呢?需要全部显示出来怎么办?
tokens=* 表示取所有元素,用%%i输出
tokens=1,2,3,4或tokens=1-4 然后用%%i或%%i,%%j,%%k,%%l 输出

其实我们还有其他的方法,比如请出delims参数
例:
@echo off
rem test.txt已经有了,就不生成了
for /f "delims=*" %%i in (test.txt) do echo %%i
pause>nul

delims是个啥玩意儿?其实这就是分割符的设定,默认以空格为分隔符,你可以将分隔符设置成其他的,你的文本就不会被分割了,delims同样支持多个分隔符,格式delims=第一个分隔符,第二个分隔符,第三个分隔符。

啊哈,还有一个skip和eol,skip表示忽略前几行,比如skip=10表示忽略这个文本的前十行,我这个文本只有4行,如果你加上skip=10的话就什么都不会输出了
eol表示忽略以某个符号开头的行,比如eol=A,当某一行的开头是A的时候,这一行就不会被处理,不过支持设置一个符号

for /f同也可以处理字符串
FOR /F ["options"] %variable IN ("string") DO command [command-parameters]
字符串需要用双引号引起来,其余用法一样,不过这里就要讲到usebackq参数了,for /f是支持处理多个文件的,文件直接用空格隔开(某些符号也可以),假如文件名中含有空格怎么办呢?那好像只能用双引号引起来了,但是用双引号引起来会被识别成字符串的,这时就要请出usebackq参数了,加上这个参数,带引号的字符串也会被识别为文件~
FOR /F ["options"] %variable IN ('command') DO command [command-parameters]

用for /f来处理命令执行的结果,命令要用单引号引起来
例:
@echo off
for /f "skip=3" %%i in ('tasklist') do echo;%%i
pause>nul

这段代码就处理了命令ipconfig的执行结果,单独键入tasklist看会出现什么?
================================================
~I - 删除任何引号(")，扩充 %I
%~fI - 将 %I 扩充到一个完全合格的路径名
%~dI - 仅将 %I 扩充到一个驱动器号
%~pI - 仅将 %I 扩充到一个路径
%~nI - 仅将 %I 扩充到一个文件名
%~xI - 仅将 %I 扩充到一个文件扩展名
%~sI - 扩充的路径只含有短名
%~aI - 将 %I 扩充到文件的文件属性
%~tI - 将 %I 扩充到文件的日期/时间
%~zI - 将 %I 扩充到文件的大小
%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩充
到找到的第一个完全合格的名称。如果环境变量名
未被定义，或者没有找到文件，此组合键会扩充到
空字符串
组合修饰符来得到多重结果:
%~dpI - 仅将 %I 扩充到一个驱动器号和路径
%~nxI - 仅将 %I 扩充到一个文件名和扩展名
%~fsI - 仅将 %I 扩充到一个带有短名的完整路径名
%~dp$PATH:i - 查找列在路径环境变量的目录，并将 %I 扩充
到找到的第一个驱动器号和路径。
%~ftzaI - 将 %I 扩充到类似输出线路的 DIR
===================================================
这些不多说了,自己用for /r命令输出的时候把%%i改成%%~nxi之类的试一试就理解了。

8、其他命令

批处理的常见命令（未列举的命令还比较多，请查阅帮助信息）
1、REM 和 ::
2、ECHO 和 @
3、PAUSE
4、ERRORLEVEL
5、TITLE
6、COLOR
7、mode 配置系统设备
8、GOTO 和 :
9、FIND
10、START
11、assoc 和 ftype
12、pushd 和 popd
13、CALL
14、shift
15、IF
16、setlocal 与变量延迟
17、ATTRIB 显示或更改文件属性

六、批处理示例

1、IF-EXIST

首先用记事本在C:\建立一个test1.bat批处理文件，文件内容如下：
@echo off
IF EXIST \AUTOEXEC.BAT TYPE \AUTOEXEC.BAT
IF NOT EXIST \AUTOEXEC.BAT ECHO \AUTOEXEC.BAT does not exist
然后运行它：
C:\>TEST1.BAT
如果C:\存在AUTOEXEC.BAT文件，那么它的内容就会被显示出来，如果不存在，批处理就会提示你该文件不存在。

2)
接着再建立一个test2.bat文件，内容如下：
@ECHO OFF
IF EXIST \%1 TYPE \%1
IF NOT EXIST \%1 ECHO \%1 does not exist
执行:
C:\>TEST2 AUTOEXEC.BAT
该命令运行结果同上。
说明：
(1) IF EXIST 是用来测试文件是否存在的，格式为
IF EXIST [路径+文件名] 命令
(2) test2.bat文件中的%1是参数，DOS允许传递9个批参数信息给批处理文件，分别为%1~%9(%0表示test2命令本身) ，这有点象编程中的实参和形参的关系，%1是形参，AUTOEXEC.BAT是实参。
3) 更进一步的，建立一个名为TEST3.BAT的文件，内容如下：
@echo off
IF "%1" == "A" ECHO XIAO
IF "%2" == "B" ECHO TIAN
IF "%3" == "C" ECHO XIN
如果运行：
C:\>TEST3 A B C
屏幕上会显示:
XIAO
TIAN
XIN
如果运行：
C:\>TEST3 A B
屏幕上会显示
XIAO
TIAN
在这个命令执行过程中，DOS会将一个空字符串指定给参数%3。

2、IF-ERRORLEVEL

建立TEST4.BAT，内容如下：
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:IF ERRORLEVEL 1 ECHO 文件拷贝失败
IF ERRORLEVEL 0 ECHO 成功拷贝文件
然后执行文件:
C:\>TEST4
如果文件拷贝成功，屏幕就会显示“成功拷贝文件”，否则就会显示“文件拷贝失败”。
IF ERRORLEVEL 是用来测试它的上一个DOS命令的返回值的，注意只是上一个命令的返回值，而且返回值必须依照从大到小次序顺序判断。因此下面的批处理文件是错误的：
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:\
IF ERRORLEVEL 0 ECHO 成功拷贝文件
IF ERRORLEVEL 1 ECHO 未找到拷贝文件
IF ERRORLEVEL 2 ECHO 用户通过ctrl-c中止拷贝操作
IF ERRORLEVEL 3 ECHO 预置错误阻止文件拷贝操作
IF ERRORLEVEL 4 ECHO 拷贝过程中写盘错误
无论拷贝是否成功，后面的：
未找到拷贝文件
用户通过ctrl-c中止拷贝操作
预置错误阻止文件拷贝操作
拷贝过程中写盘错误
都将显示出来。

七、命令返回值

1、backup

0 备份成功
1 未找到备份文件
2 文件共享冲突阻止备份完成
3 用户用ctrl-c中止备份
4 由于致命的错误使备份操作中止

2、diskcomp

0 盘比较相同
1 盘比较不同
2 用户通过ctrl-c中止比较操作
3 由于致命的错误使比较操作中止
4 预置错误中止比较

3、diskcopy

0 盘拷贝操作成功
1 非致命盘读/写错
2 用户通过ctrl-c结束拷贝操作
3 因致命的处理错误使盘拷贝中止
4 预置错误阻止拷贝操作

4、format

0 格式化成功
3 用户通过ctrl-c中止格式化处理
4 因致命的处理错误使格式化中止
5 在提示“proceed with format（y/n）?”下用户键入n结束

5、xcopy

0 成功拷贝文件
1 未找到拷贝文件
2 用户通过ctrl-c中止拷贝操作
4 预置错误阻止文件拷贝操作
5 拷贝过程中写盘错误

八、特殊符号

1、@-隐藏命令

开启了echo off能够起到隐藏命令的效果,而@同样能起到这个效果,只不过需要在每条命令前面都加一个...

2、&&,||-判断

还记得用if errorlevel来判断命令成功与否吗?&&和||同样能起到这个效果,&&表示前面的命令成功以后执行后面的命令,||反之
例:
@echo;>>%SystemRoot%\system32\test.txt&&echo 成功!||echo 失败
@pause>nul

3、|-管道

将前一个命令执行的结果发送给后一个命令
例:
@echo 你好|find "你"
@tasklist|find "exe"

4、&-分行符

可以把几个命令写在同一行
例:
@echo 123&@echo 456
pause>nul

5、^-分行与转义符

　　1）分行

　　可以把一个命令写成多行哦
例:
@echo 1^
2^
3^
4
@pause>nul
复制上面的命令,执行结果是什么?这就是分行符的作用

　　2）转义

当我们试图输出一个&的时候,我们会发现输出不了...因为它被当成分行符处理了
这时就要请出转义符^了,它可以剥夺后面第一个符号的特殊地位,变为普通符号(这其实是一个很神奇的功能,之所以神奇...赘不详述)
例:
@echo ^&
@pause>nul
这样就输出了&
另外，当存在a变量（前面set /p a=或set a=给a赋值了）想要输出%a%，一是可以用转义符^，还可以：
echo %%a%%
这样既可将两个百分号识别为一个，起到了转义的作用
还有些特殊情况不需要转义：
echo "0000|000"
用引号括起来可以起到一定的转义的作用，包括set "a=a的值"等
但特别特殊的情况比如获取%1时存在转义符很难处理，没办法正常引用

　　3）*,?-通配符

啥叫通配符?举个例子吧,*.jpg表示所有的jpg,*表示所有文件.现在你明白了吗? 那"?"有什么用,*可以为任意字符,但?只表示一个字符,比如?.jpg只表示文件名只有一个的jpg文件,比如1.jpg,比.jpg什么

　　4）()-括起来

括起来的语句是一个整体

　　5）>,>>,<-重定向

在这里请注意: 在重定向符号 ">" 以及 ">>" 前必须添加空格以防万一，因为Batch具有不唯一性所以在很多时候不加空格也能正常使用。但是日常使用中必须添加空格否则失败的几率很大，要么是无法创建/输出，要么文件是空的。
请不要使用不添加空格的不正确用法！
echo 123 >>one.txt
可以输出123追加到one.txt中
echo 123 >one.txt
可以输出123覆盖one.txt中原先的内容
nul是一个系统保留字,所以>nul不会输出到任何文件,可以起到隐藏命令执行结果的效果
2 >nul可以起到隐藏命令失败执行结果的效果
<可以从文件中读取数据到某个命令中,不过这个命令得等待用户输入
例:
@echo off
echo 123 >>00.txt
set /p num=<00.txt
echo 数字是%num%
pause>nul
有些命令不止需要一个>nul，如要连接，需要：>nul 2>nul以此类推
如果前面有数字，需要添加空格
ping >nul 2>nul
=1>nul 2>nul ping
=ping >nul 2>&1.... X>&2 X>&2 X>&3等
nul指空设备，简单来说就是隐藏输出。
2>&1 3>&2 可以一直接下去，&1 &2就是引用第一个、第二个等

> 创建一个文件
>> 追加到一个文件后面
@ 前缀字符.表示执行时本行在cmd里面不显示, 可以使用 echo off关闭显示
^ 对特殊符号( > < &)的前导字符. 第一个只是显示aaa 第二个输出文件bbb
() 包含命令
, 和空格一样的缺省分隔符号.
; 注释,表示后面为注释
: 标号作用
|管道操作
& Usage：第一条命令 & 第二条命令 [& 第三条命令...] 用这种方法可以同时执行多条命令，而不管命令是否执行成功
&& Usage：第一条命令 && 第二条命令 [&& 第三条命令...]当碰到执行出错的命令后将不执行后面的命令，如果一直没有出错则一直执行完所有命令；
|| Usage：第一条命令 || 第二条命令 [|| 第三条命令...]当碰到执行正确的命令后将不执行后面的命令，如果没有出现正确的命令则一直执行完所有命令；
eol=c - 指一个行注释字符的结尾(就一个)
skip=n - 指在文件开始时忽略的行数。
delims=xxx - 指分隔符集。这个替换了空格和跳格键的默认分隔符集。
== - 等于
EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于
选择开关/i则不区分字符串大小写；选择not项，则对判断结果进行逻辑非。

九、命令帮助

###########################

ver
cmd /?
set /?
rem /?
if /?
echo /?
goto /?
for /?
shift /?
call /?
其他需要的常用命令
type /?
find /?
findstr /?
copy /?
下面将所有上面的帮助输出到一个文件
echo ver >tmp.txt
ver >>tmp.txt
echo cmd /? >>tmp.txt
cmd /? >>tmp.txt
echo rem /? >>tmp.txt
rem /? >>tmp.txt
echo if /? >>tmp.txt
if /? >>tmp.txt
echo goto /? >>tmp.txt
goto /? >>tmp.txt
echo for /? >>tmp.txt
for /? >>tmp.txt
echo shift /? >>tmp.txt
shift /? >>tmp.txt
echo call /? >>tmp.txt
call /? >>tmp.txt
echo type /? >>tmp.txt
type /? >>tmp.txt
echo find /? >>tmp.txt
find /? >>tmp.txt
echo findstr /? >>tmp.txt
findstr /? >>tmp.txt
echo copy /? >>tmp.txt
copy /? >>tmp.txt
type tmp.txt

十、实际应用

开机后一键启动程序

@echo off
::启动QQ
start "" "D:\Program Files\Tencent\QQLite\Bin\QQScLauncher.exe" /forceuninstall

::启动eDiary
start "" "D:\Program Files\ed253_setup\eDiary-3.2\eDiary.exe" /forceuninstall

::启动Foxmail
start "" "D:\Program Files\Foxmail 7.0\Foxmail.exe" /forceuninstall

::启动WeChat
start "" "D:\Program Files\Tencent\WeChat\WeChat.exe" /forceuninstall

::启动ie浏览器
start "" "C:\Program Files\Internet Explorer\iexplore.exe" /forceuninstall

::启动360浏览器
start "" "D:\Program Files\360\360Chrome\Chrome\Application\360chrome.exe" /forceuninstall

本文章为转载内容，我们尊重原作者对文章享有的著作权。如有内容错误或侵权问题，欢迎原作者联系我们进行内容更正或删除文章。