ASP上传达图片到数据库&从数据库中显示图片到网页=======================================================================
第一部分：
首先我们先来熟悉一下将要使用的对象方法。我们用来获取上一个页面传
递过来的数据一般是使用Request对象。同样的，我们也可以使用Request对象
来获取上传上来的文件数据，使用的方法是Request.BinaryRead()。而我们要从
数据库中读出来图片的数据显示到网页上面要用到的方法是：
Request.BinaryWrite()。在我们得到了图片的数据，要保存到数据库中的时候，
不可以直接使用Insert语句对数据库进行操作，而是要使用ADO的
AppendChunk方法，同样的，读出数据库中的图片数据，要使用GetChunk方
法。各个方法的具体语法如下：
* Request.BinaryRead语法：
variant = Request.BinaryRead(count)
参数
variant
返回值保存着从客户端读取到数据。
count指明要从客户端读取的数据量大小，这个值小于或者等于使用方法
Request.TotalBytes得到的数据量。
=======================================================================
第二部分：
* Request.BinaryWrite语法：
Request.BinaryWrite data
参数
data
要写入到客户端浏览器中的数据包。
* Request.TotalBytes语法：
variant = Request.TotalBytes
参数
variant返回从客户端读取到数据量的字节数。
=======================================================================
第三部分：
* AppendChunk语法
将数据追加到大型文本、二进制数据 Field 或 Parameter 对象。
object.AppendChunk Data参数
object Field 或 Parameter 对象
Data 变体型，包含追加到对象中的数据。
说明
使用 Field 或 Parameter 对象的 AppendChunk 方法可将长二进制或字符数
据填写到对象中。在系统内存有限的情况下，可以使用 AppendChunk 方法对长
整型值进行部分而非全部的操作。
=======================================================================
第四部分：
* GetChunk语法
返回大型文本或二进制数据 Field 对象的全部或部分内容 。
variable = field.GetChunk( Size )返回值
返回变体型。
参数
Size 长整型表达式，等于所要检索的字节或字符数。
说明
使用 Field 对象的 GetChunk 方法检索其部分或全部长二进制或字符数据。
在系统内存有限的情况下，可使用 GetChunk 方法处理部分而非全部的长整型
值。
GetChunk 调用返回的数据将赋给“变量”。如果 Size 大于剩余的数据，则
GetChunk 仅返回剩余的数据而无需用空白填充“变量”。如果字段为空，则
GetChunk 方法返回 Null。
=======================================================================
第五部分：
每个后续的 GetChunk 调用将检索从前一次 GetChunk 调用停止处开始的数
据。但是，如果从一个字段检索数据然后在当前记录中设置或读取另一个字段
的值，ADO 将认为已从第一个字段中检索出数据。如果在第一个字段上再次调
用 GetChunk 方法，ADO 将把调用解释为新的 GetChunk 操作并从记录的起始
处开始读取。如果其他 Recordset 对象不是首个 Recordset 对象的副本，则
访问其中的字段不会破坏 GetChunk 操作。
如果 Field 对象的 Attributes 属性中的 adFldLong 位设置为 True，则可
以对该字段使用 GetChunk 方法。
如果在 Field 对象上使用 Getchunk 方法时没有当前记录，将产生错误 3021
（无当前记录）。
=======================================================================
第六部分：
Access数据库:
字段名称 类型 描述
id 自动编号 主键值
img OLE对象 用来保存图片数据
对于在MS SQL Server7中，对应的结构如下：
字段名称 类型 描述
id int(Identity) 主键值
img image 用来保存图片数据
现在开始正式编写我们的纯ＡＳＰ代码上传部分了，首先，我们有一个提
供给用户的上传界面，可以让用户选择要上传的图片。代码如下
（upload.htm）：
<HTML>
<HEAD>
<title>上传文件到数据库</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<style type="text/css">
<!--
.STYLE1 {
font-size: 18px;
font-weight: bold;
}
-->
</style>
</HEAD>
<body>
<p align=center> </p>
<p align=center><FORM action="process.asp" method="post" enctype="multipart/form-data">
<table width="500" border="1" align="center" cellpadding="0" cellspacing="0" style="border-collapse:collapse;">
<tr>
<td height="40" align="center"><span class="STYLE1">上传文件到数据库</span></td>
</tr>
<tr>
<td height="30">选择上传文件：
<input id="upfile" type="file" name="upfile" size="40"></td>
</tr>
<tr>
<td height="30" align="center"><input id="Upload" type="submit" value="上传" name="Upload">
<input type="reset" name="Submit" value="重置"></td>
</tr>
</table>
<BR>
</form></p>
</BODY>
</HTML>注意代码中黑色斜体的部分，一定要在Form中有这个属性，否则，将无
法得到上传上来的数据。
接下来，我们要在process.asp中对从浏览器中获取的数据进行必要的处
理，因为我们在process.asp中获取到的数据不仅仅包含了我们想要的上传上来
的图片的数据，也包含了其他的无用的信息，我们需要剔除冗余数据，并将处
理过的图片数据保存到数据库中，这里我们以Ａｃｃｅｓｓ９７为例。具体代
码如下（process.asp）：
<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%
Response.Buffer=True
formsize=Request.TotalBytes
formdata=Request.BinaryRead(formsize)
vCrLf=ChrB(13) & ChrB(10)
divider=LeftB(formdata,clng(instrb(formdata,vCrLf))-1)
datastart=InStrB(formdata,vCrLf & vCrLf)+4
dataend=InStrB(datastart+1,formdata,divider)-datastart
mydata=MidB(formdata,datastart,dataend)
set conn=server.CreateObject("ADODB.connection")
conn.open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.Mappath("images.mdb")
set rs=server.createobject("ADODB.recordset")
rs.Open "SELECT * FROM images where id is null",conn,1,3
rs.addnew
rs("img").appendchunk mydata
rs.update
rs.Update
rs.Close
Set rs=nothing
Set conn=nothing
Response.Write "图片上传成功，已保存到数据库中！"
%>
<HTML><HEAD>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<TITLE>上传文件成功</TITLE>
<mce:style type="text/css"><!--
.STYLE1 {
font-size: 18px;
font-weight: bold;
}
--></mce:style><style type="text/css" mce_bogus="1">.STYLE1 {
font-size: 18px;
font-weight: bold;
}</style>
</HEAD>
<BODY>
</BODY>
</HTML>=======================================================================
第七部分：
好了，这下我们就把上传来的图片保存到了名为images.mdb的数据库中
了，剩下的工作就是要将数据库中的图片数据显示到网页上面了。一般在ＨＴ
ＭＬ中，显示图片都是使用<IMG>标签，也就是<IMG SRC="图片路径">，但
是我们的图片是保存到了数据库中，“图片路径”是什么呢？呵呵，其实这个
SRC属性除了指定路径外，也可以这样使用哦：
<IMG SRC="showimg.asp?id=xxx">所以，我们所要做的就是在showimg.asp中从数据库中读出来符合条件的
数据，并返回到SRC属性中就可以了，具体代码如下（showimg.asp）：
<%
set connGraph=server.CreateObject("ADODB.connection")
connGraph.ConnectionString="driver={Microsoft Access Driver (*.mdb)};DBQ=" &server.MapPath("images.mdb")
connGraph.Open
set rec=server.createobject("ADODB.recordset")
strsql="select img from images where id=" & trim(request("id"))
rec.open strsql,connGraph,1,1
Response.ContentType = "image/*"
Response.BinaryWrite rec("img").getChunk(7500000)
rec.close
set rec=nothing
set connGraph=nothing
%>注意在输出到浏览器之前一定要指定Response.ContentType = "image/*"，
以便正常显示图片。
最后要注意的地方是，我的process.asp中作的处理没有考虑到第一页
(upload.htm)中还有其他数据，比如<INPUT type=tesxt name=userid>等等，如果
有这些项目，你的process.asp就要注意处理掉不必要的数据。
