外向交货单批次拆分
目录
外向交货单批次拆分
一、前台操作
二、BAPI处理
三、库表字段
四、备注：
一、前台操作
VL02N
选中行，点批次拆分
填写批次后，回车，会将项目号和库位自动带出（视具体配置而定）
点保存后，原来航项目10数量自动变更
删除拆分：
选中拆分项目，点删除
10主行项目数量会自动更新
二、BAPI处
REPORT YLM_TEST045.
PARAMETERS P_VBELN TYPE VBELN_VL DEFAULT '8000003765'.
"测试批次拆分
DATA:
IT_HEADER_PARTNER LIKE TABLE OF BAPIDLVPARTNERCHG ,"交货：合作伙伴更改
IT_HEADER_DEADLINES LIKE TABLE OF BAPIDLVDEADLN ,"交货截止日期
IT_ITEM_DATA LIKE TABLE OF BAPIOBDLVITEMCHG ,"更改外向交货拣配数据项目等级
IT_ITEM_CONTROL LIKE TABLE OF BAPIOBDLVITEMCTRLCHG ,"外向交货项目级别控制数据
ET_RETURN LIKE TABLE OF BAPIRET2 WITH HEADER LINE ,"返回参数
IT_ITEM_DATA_SPL LIKE TABLE OF /SPE/BAPIOBDLVITEMCHG ,"更改向外交货拣配数据项目等级（SPE）
IS_HEADER_DATA LIKE BAPIOBDLVHDRCHG ,"更改外向交货拣配数据表头等级
IS_HEADER_CONTROL LIKE BAPIOBDLVHDRCTRLCHG ,"外向交货标题级别控制数据
IV_DELIVERY LIKE BAPIOBDLVHDRCHG-DELIV_NUMB ."交货
DATA:
LW_HEADER_PARTNER LIKE BAPIDLVPARTNERCHG ,"交货：合作伙伴更改
LW_HEADER_DEADLINES LIKE BAPIDLVDEADLN ,"交货截止日期
LW_ITEM_DATA LIKE BAPIOBDLVITEMCHG ,"更改外向交货拣配数据项目等级
LW_ITEM_CONTROL LIKE BAPIOBDLVITEMCTRLCHG ,"外向交货项目级别控制数据
LW_RETURN LIKE BAPIRET2 ."返回参数
DATA: L_TECHN_CONTROL TYPE BAPIDLVCONTROL.
DATA:
LS_ITEM TYPE BAPIOBDLVITEMCHG,
LS_ITEM_T TYPE BAPIOBDLVITEMCHG,
LS_ITEM_CONTROL TYPE BAPIOBDLVITEMCTRLCHG,
LS_DEADLINES TYPE BAPIDLVDEADLN.
IV_DELIVERY = P_VBELN. "交货单号
"头信息
IS_HEADER_DATA-DELIV_NUMB = P_VBELN. "交货单号
IS_HEADER_CONTROL-DELIV_NUMB = P_VBELN.
"修改原10行项目数量
CLEAR LW_ITEM_DATA.
LW_ITEM_DATA-DELIV_NUMB = P_VBELN.
LW_ITEM_DATA-DELIV_ITEM = 10. "原行项目
LW_ITEM_DATA-DLV_QTY = 1.
LW_ITEM_DATA-DLV_QTY_IMUNIT = 1.
LW_ITEM_DATA-BASE_UOM = 'TO'. "基本单位
LW_ITEM_DATA-SALES_UNIT = 'TO'. "销售单位
LW_ITEM_DATA-FACT_UNIT_NOM = 1. "销售数量转换成SKU的分子(因子)
LW_ITEM_DATA-FACT_UNIT_DENOM = 1. "销售数量转换为 SKU 的值（除数）
APPEND LW_ITEM_DATA TO IT_ITEM_DATA .
CLEAR LW_ITEM_CONTROL.
LW_ITEM_CONTROL-DELIV_NUMB = P_VBELN.
LW_ITEM_CONTROL-DELIV_ITEM = 10. "原行项目
LW_ITEM_CONTROL-CHG_DELQTY = 'X'. "数量修改标志
APPEND LW_ITEM_CONTROL TO IT_ITEM_CONTROL.
"新拆分的批次
CLEAR LW_ITEM_DATA.
LW_ITEM_DATA-DELIV_NUMB = P_VBELN.
LW_ITEM_DATA-DELIV_ITEM = '900001'. "拆分后的新行项目
LW_ITEM_DATA-HIERARITEM = 10. "上级行项目
LW_ITEM_DATA-BATCH = 'YS91480001'. "新批次
LW_ITEM_DATA-DLV_QTY = 1. "自己重新计算拆分后的数量，
LW_ITEM_DATA-DLV_QTY_IMUNIT = 1.
LW_ITEM_DATA-FACT_UNIT_NOM = 1. "销售数量转换成SKU的分子(因子)
LW_ITEM_DATA-FACT_UNIT_DENOM = 1. "销售数量转换为 SKU 的值（除数）
LW_ITEM_DATA-BASE_UOM = 'TO'. "基本单位
LW_ITEM_DATA-SALES_UNIT = 'TO'. "销售单位
LW_ITEM_DATA-USEHIERITM = '1'.
APPEND LW_ITEM_DATA TO IT_ITEM_DATA.
CLEAR LW_ITEM_DATA.
LW_ITEM_DATA-DELIV_NUMB = P_VBELN.
LW_ITEM_DATA-DELIV_ITEM = '900002'. "拆分后的新行项目
LW_ITEM_DATA-HIERARITEM = 10. "上级行项目
LW_ITEM_DATA-BATCH = 'YS91480002'."新批次
LW_ITEM_DATA-DLV_QTY = 1.
LW_ITEM_DATA-DLV_QTY_IMUNIT = 1.
LW_ITEM_DATA-FACT_UNIT_NOM = 1. "销售数量转换成SKU的分子(因子)
LW_ITEM_DATA-FACT_UNIT_DENOM = 1. "销售数量转换为 SKU 的值（除数）
LW_ITEM_DATA-BASE_UOM = 'TO'. "基本单位
LW_ITEM_DATA-SALES_UNIT = 'TO'. "销售单位
LW_ITEM_DATA-USEHIERITM = '1'.
APPEND LW_ITEM_DATA TO IT_ITEM_DATA.
CLEAR LW_ITEM_CONTROL.
LW_ITEM_CONTROL-DELIV_NUMB = P_VBELN.
LW_ITEM_CONTROL-DELIV_ITEM = '900001'. "拆分后的新行项目
LW_ITEM_CONTROL-CHG_DELQTY = 'X'. "数量修改标志
APPEND LW_ITEM_CONTROL TO IT_ITEM_CONTROL .
CLEAR LW_ITEM_CONTROL.
LW_ITEM_CONTROL-DELIV_NUMB = P_VBELN.
LW_ITEM_CONTROL-DELIV_ITEM = '900002'."拆分后的新行项目
LW_ITEM_CONTROL-CHG_DELQTY = 'X'. "数量修改标志
APPEND LW_ITEM_CONTROL TO IT_ITEM_CONTROL .
CALL FUNCTION 'BAPI_OUTB_DELIVERY_CHANGE'
EXPORTING
HEADER_DATA = IS_HEADER_DATA
HEADER_CONTROL = IS_HEADER_CONTROL
DELIVERY = IV_DELIVERY
TABLES
HEADER_PARTNER = IT_HEADER_PARTNER
HEADER_DEADLINES = IT_HEADER_DEADLINES
ITEM_DATA = IT_ITEM_DATA
ITEM_CONTROL = IT_ITEM_CONTROL
RETURN = ET_RETURN
* ITEM_DATA_SPL = IT_ITEM_DATA_SPL
.
DATA: L_MSG TYPE STRING.
IF ET_RETURN[] IS INITIAL.
COMMIT WORK AND WAIT.
WRITE:/ '批次拆分成功'.
RETURN.
ENDIF.
LOOP AT ET_RETURN WHERE TYPE = 'E'.
CLEAR L_MSG.
MESSAGE ID ET_RETURN-ID
TYPE 'E'
NUMBER ET_RETURN-NUMBER
WITH ET_RETURN-MESSAGE_V1
ET_RETURN-MESSAGE_V2
ET_RETURN-MESSAGE_V3
ET_RETURN-MESSAGE_V4
INTO L_MSG.
WRITE:/ L_MSG.
ENDLOOP.
三、库表字段
主要字段：LIPS~ UECHA：批次拆分项目的上层项目
LIKP
LIPS
VBFA: 销售凭证流
四、备注：
BAPI中table参数：ITEM_DATA_SPL
这个结构
主要是给库存地点赋值的。
具体可能跟配置有关，比如我这里，及时bapi里写入了值，也不能进行修改
最后在增强里处理的：
BADI：LE_SHP_DELIVERY_PROC
方法：CHANGE_DELIVERY_ITEM
修改的参数：CS_LIPS
直接把库存地点赋值到这里即可
至于
LW_ITEM_DATA-USEHIERITM = '1'. 为啥赋值为1
请点进去自行查看！
