PhotoSprite

-- 建立表 --
CREATE TABLE [TestTable] (
    [ID] [int] IDENTITY (1, 1) NOT NULL ,
    [FirstName] [nvarchar] (100) COLLATE Chinese_PRC_CI_AS NULL ,
    [LastName] [nvarchar] (100) COLLATE Chinese_PRC_CI_AS NULL , 
    [Country] [nvarchar] (50) COLLATE Chinese_PRC_CI_AS NULL ,
    [Note] [nvarchar] (2000) COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY]
GO

 

-- 插入数据：(2万条，用更多的数据测试会明显一些) --
SET IDENTITY_INSERT TestTable ON

Declare @i int 
Set @i=1 
While @i<=20000 
Begin 
    Insert Into TestTable([id], FirstName, LastName, Country,Note) 
    Values(@i, 'FirstName_XXX', 'LastName_XXX', 'Country_XXX', 'Note_XXX')

    Set @i=@i+1 
End

SET IDENTITY_INSERT TestTable OFF

 

-- 分页方案一：(利用Not In和SELECT TOP分页) 
SELECT TOP 10 *
FROM TestTable
WHERE (ID NOT IN
        (
        SELECT TOP 20 ID
        FROM TestTable
        ORDER BY ID)
      )
ORDER BY ID

/*  方法
SELECT TOP 页大小 *
FROM 表
WHERE (ID NOT IN
        (
        SELECT TOP 页大小*页数 ID
        FROM 表
        ORDER BY ID)
      )
ORDER BY ID
*/

 

-- 分页方案二：(利用ID大于多少和SELECT TOP分页）
SELECT TOP 10 *
FROM TestTable
WHERE (ID > (
               SELECT MAX(id)
               FROM (
                       SELECT TOP 20 id
                       FROM TestTable
                       ORDER BY id
                    ) T
             )
       )
ORDER BY ID

/*  方法
SELECT TOP 页大小 *
FROM 表
WHERE (ID > (
               SELECT MAX(id)
               FROM (
                       SELECT TOP 页大小*页数 id
                       FROM 表
                       ORDER BY id
                    ) T
             )
       )
ORDER BY ID
*/

 

-- 分页方案三：(利用SQL的游标存储过程分页)
CREATE PROCEDURE sp_pagination
    @sql nvarchar(4000), --查询字符串
    @currentpage int, --第N页
    @pagesize int --每页行数
AS

SET NOCOUNT ON

Declare @P1 int, --P1是游标的id
        @rowcount int

exec sp_cursoropen @P1 output, @sql, @scrollopt=1, @ccopt=1, @rowcount=@rowcount output

Select ceiling(1.0 * @rowcount / @pagesize) AS 总页数, @rowcount AS 总行数, @currentpage AS 当前页
Set @currentpage=(@currentpage-1)*@pagesize+1

exec sp_cursorfetch @P1,16,@currentpage,@pagesize
exec sp_cursorclose @P1

SET NOCOUNT OFF

 

其它的方案：如果没有主键，可以用临时表，也可以用方案三做，但是效率会低。
建议优化的时候，加上主键和索引，查询效率会提高。

通过SQL 查询分析器，显示比较：我的结论是:
分页方案二：(利用ID大于多少和SELECT TOP分页）效率最高，需要拼接SQL语句
分页方案一：(利用Not In和SELECT TOP分页) 效率次之，需要拼接SQL语句
分页方案三：(利用SQL的游标存储过程分页) 效率最差，但是最为通用