数据库的自动备份

转载

mb5fdb0f269f12c 2012-08-01 15:18:00

文章标签 数据库备份文件 sql 数据右键 文章分类 代码人生

常常人工备份是不现实的，一定要系统自动定期备份。

备份思想：

0、定期备份，非作业莫属。

1、重要的数据应该每几个小时就做一次差异备份；普通数据每周做一次。（我们的数据库是简单恢复模式）

2、硬盘容量有限，数据库又很大，不能容纳太多备份文件，采用2个备份文件策略，轮流覆盖。所以每个数据库永远都只有2个备份文件。

备份作业：

1、获取单双周函数，用于确定备份文件名称。保持每个数据库永远只有2个备份文件

USE [Master]
GO

-- =============================================
-- Author:    leftfist
-- Create date: 2010
-- Description: 用于为备份文件起名
-- =============================================
CREATE FUNCTION [dbo].[jo_func_byWeek]
(
)
RETURNS TINYINT
AS
BEGIN
  DECLARE @JO INT;
  SET @JO = CONVERT(INT,DATENAME(ww,GETDATE()));
  RETURN (@JO % 2);
END

2、根据数据库名称，创建同名文件夹，用于存放备份文件

EXEC sp_configure 'show advanced options', 1
GO
RECONFIGURE
GO
EXEC sp_configure 'xp_cmdshell', 1
GO
RECONFIGURE
GO

DECLARE @folder VARCHAR(300);
SET @folder = 'c:\backup\db\';
DECLARE @name VARCHAR(50);
DECLARE @sql VARCHAR(1000);
DECLARE curT CURSOR FOR SELECT name FROM sys.databases where database_id<>2;
OPEN curT;
FETCH NEXT FROM curT INTO @name;
WHILE @@FETCH_STATUS = 0
BEGIN
    SET @sql = 'mkdir ' + @folder + @name;
    ExEc xp_cmdshell @sql;
    FETCH NEXT FROM curT INTO @name;
END
CLOSE curT;
DEALLOCATE curT;

EXEC sp_configure 'xp_cmdshell', 0
GO
RECONFIGURE
GO
EXEC sp_configure 'show advanced options', 0
GO
RECONFIGURE
GO

3、备份所有数据库（tempdb除外）

USE [master]
GO

DECLARE @name VARCHAR(50);
declare @sql varchar(1000);
DECLARE @jo TINYINT;
DECLARE @filename NVARCHAR(100);

--[jo_func_byWeek]是自定义函数，单周返回0，双周返回1
SET @jo = [Master].dbo.[jo_func_byWeek]();
--备份所有数据库（tempdb除外）
DECLARE curT CURSOR FOR SELECT name FROM sys.databases where database_id<>2
OPEN curT;
FETCH NEXT FROM curT INTO @NAME;
WHILE @@FETCH_STATUS = 0
BEGIN
    --每个数据库存放于同名的文件夹。文件夹预先建好
    SET @filename = @name + '\' + @name + '_' + CAST(@jo AS CHAR(1)) + '.bak';
    SET @sql='BACKUP DATABASE [' + @name + '] TO DISK = ''C:\backup\db\' + @filename + ''' WITH INIT , NAME = N''' + @name + ''', NOSKIP , STATS = 10, NOFORMAT';
    EXEC(@sql);    
    FETCH NEXT FROM curT INTO @name;
END
CLOSE curT;
DEALLOCATE curT;