cmake配置python cmake

转载

charlesc 2023-11-10 22:29:30

文章标签 cmake配置python c++ c语言 CMake 动态库 文章分类 Python 后端开发

文章目录

一、什么是cmake？
二、cmake快速使用例子
三、CMake关键字介绍

project关键字
set关键字
message关键字
add_executable关键字
target_include_directories关键字
链接库target_link_libraries
add_subdirectory 指令
更改二进制的保存路径
安装
静态库和动态库的构建任务：
find_package包含第三方库

三、CMake语法

1.语法的基本原则
2.语法注意事项
3.内部构建和外部构建

四、CMake构建级别

一、什么是cmake？

cmake的定义是什么？-----⾼级编译配置⼯具
cmake就是将多个cpp、hpp文件组合构建为一个大工程的语言。他能够输出各种各样的makefile或者project文件，所有操作都是通过编译CMakeLists.txt来完成。

二、cmake快速使用例子

1.步骤⼀，写⼀个HelloWord

#main.cpp
#include <iostream>
int main(){
std::cout << "hello word" << std::endl; }

2、步骤二，写CMakeLists.txt

#CMakeLists.txt

project (HELLO)

set(SRC_LIST main.cpp)

message(STATUS "This is BINARY dir " ${HELLO_BINARY_DIR})

message(STATUS "This is SOURCE dir "${HELLO_SOURCE_DIR})

add_executable(hello ${SRC_LIST})

3、步骤三、使用cmake，生成makefile文件

cmake .

输出：
[root@localhost cmake]# cmake .
CMake Warning (dev) in CMakeLists.txt:
  Syntax Warning in cmake code at

    /root/cmake/CMakeLists.txt:7:37

  Argument not separated from preceding token by whitespace.
This warning is for project developers.  Use -Wno-dev to suppress it.

-- The C compiler identification is GNU 10.2.1
-- The CXX compiler identification is GNU 10.2.1
-- Check for working C compiler: /usr/bin/cc
-- Check for working C compiler: /usr/bin/cc -- works
-- Detecting C compiler ABI info
-- Detecting C compiler ABI info - done
-- Check for working CXX compiler: /usr/bin/c++
-- Check for working CXX compiler: /usr/bin/c++ -- works
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done
-- This is BINARY dir /root/cmake
-- This is SOURCE dir /root/cmake
-- Configuring done
-- Generating done
-- Build files have been written to: /root/cmake

目录下就生成了这些文件-CMakeFiles, CMakeCache.txt, cmake_install.cmake 等文件，并且生成了Makefile.
现在不需要理会这些文件的作用，以后你也可以不去理会。最关键的是，它自动生成了Makefile.

4、使用make命令编译

root@localhost cmake]# make
Scanning dependencies of target hello
[100%] Building CXX object CMakeFiles/hello.dir/main.cpp.o
Linking CXX executable hello
[100%] Built target hello

5、最终生成了Hello的可执行程序

三、CMake关键字介绍

project关键字

可以用来指定工程的名字和支持的语言，默认支持所有语言

project (HELLO)   指定了工程的名字，并且支持所有语言

上面的命令会自动生成一些变量，如生成了PROJECT_BINARY_DIR和PROJECT_SOURCE_DIR，这两个变量和
_BINARY_DIR，本例中是 HELLO_BINARY_DIR 和_SOURCE_DIR，本例中是 HELLO_SOURCE_DIR 是一致的

set关键字

用来显示的指定变量的

set(SRC_LIST main.cpp)    #SRC_LIST变量就包含了main.cpp
set(SOURCES
    src/Hello.cpp
    src/main.cpp
)#创建一个变量，名字叫SOURCE。它包含了所有的cpp文件。

message关键字

向终端输出用户自定义的信息

主要包含三种信息：

SEND_ERROR，产生错误，生成过程被跳过。
SATUS，输出前缀为—的信息。
FATAL_ERROR，立即终止所有 cmake 过程.

add_executable关键字

生成可执行文件

add_executable(hello_code ${SRC_LIST})     #生成的可执行文件名是hello_code，源文件读取变量SRC_LIST中的内容

也可以直接写 add_executable(hello_code main.cpp)

target_include_directories关键字

当您有其他需要包含的文件夹（文件夹里有头文件）时，可以使用以下命令使编译器知道它们： target_include_directories（）。编译此目标时，这将使用-I标志将这些目录添加到编译器中，例如 -I /目录/路径

设置这个可执行文件hello_code需要包含的库的路径

target_include_directories(hello_code PRIVATE  ${PROJECT_SOURCE_DIR}/include)

链接库target_link_libraries

创建将使用这个库的可执行文件时，必须告知编译器需要用到这个库。可以使用target_link_library（）函数完成此操作。add_executable()连接源文件，target_link_libraries()连接库文件。

add_executable(hello_binary src/main.cpp)

target_link_libraries( hello_binary PRIVATE hello_library
)

这告诉CMake在链接期间将hello_library链接到hello_binary可执行文件。同时，这个被链接的库如果有INTERFACE或者PUBLIC属性的包含目录，那么，这个包含目录也会被传递（ propagate ）给这个可执行文件。

add_subdirectory 指令

add_subdirectory(source_dir [binary_dir] [EXCLUDE_FROM_ALL])

这个指令用于向当前工程添加存放源文件的子目录，并可以指定中间二进制和目标二进制存放的位置
EXCLUDE_FROM_ALL函数是将写的目录从编译中排除
add_subdirectory(src bin)
将 src 子目录加入工程并指定编译输出(包含编译中间结果)路径为bin 目录
如果不进行 bin 目录的指定，那么编译结果(包括中间结果)都将存放在build/src 目录
示例：每个目录下都要有一个CMakeLists.txt说明

//目录结构
[root@localhost cmake]# tree
.
├── build
├── CMakeLists.txt
└── src
    ├── CMakeLists.txt
    └── main.cpp

//外层CMakeLists.txt
project(HELLO)
add_subdirectory(src bin)

//src下的CMakeLists.txt
add_executable(hello main.cpp)

更改二进制的保存路径

set 指令重新定义 EXECUTABLE_OUTPUT_PATH 和 LIBRARY_OUTPUT_PATH 变量来指定最终的目标二进制的位置

set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)

CMake语法指定了许多变量如下：

cmake配置python cmake_c语言

安装

install(FILES COPYRIGHT README DESTINATION share/doc/cmake/)
FILES：文件
DESTINATION：路径
1、写绝对路径
2、可以写相对路径，相对路径实际路径是：${CMAKE_INSTALL_PREFIX}/<DESTINATION 定义的路径>
CMAKE_INSTALL_PREFIX 默认是在 /usr/local/
cmake -D CMAKE_INSTALL_PREFIX=/usr 在cmake的时候指定CMAKE_INSTALL_PREFIX变量的路径

install的安装可以包括：二进制、动态库、静态库以及文件、目录、脚本等

# 目录树结构
[root@localhost cmake]# tree
.
├── build
├── CMakeLists.txt
├── COPYRIGHT
├── doc
│   └── hello.txt
├── README
├── runhello.sh
└── src
    ├── CMakeLists.txt
    └── main.cpp

# 安装文件COPYRIGHT和README
install(FILES COPYRIGHT README DESTINATION share/doc/cmake/)

# 安装脚本runhello.sh
#PROGRAMS：非目标文件的可执行程序安装(比如脚本之类)
install(PROGRAMS runhello.sh DESTINATION bin)

# 安装 doc 中的 hello.txt
install(DIRECTORY doc/ DESTINATION share/doc/cmake)

静态库和动态库的构建任务：

命令：ADD_LIBRARY
add_library(hello SHARED ${LIBHELLO_SRC})

hello：就是正常的库名，生成的名字前面会加上lib，最终产生的文件是libhello.so
SHARED，动态库 STATIC，静态库
${LIBHELLO_SRC} ：源文件

静态库和动态库的区别

静态库的扩展名一般为“.a”或“.lib”；动态库的扩展名一般为“.so”或“.dll”。
静态库在编译时会直接整合到目标程序中，编译成功的可执行文件可独立运行
动态库在编译时不会放到连接的目标程序中，即可执行文件无法单独运行。
例子：

[root@localhost cmake2]# tree
.
├── build
├── CMakeLists.txt
└── lib
    ├── CMakeLists.txt
    ├── hello.cpp
    └── hello.h

#项目中的cmake内容
project(HELLO)
add_subdirectory(lib bin)

#lib中CMakeLists.txt中的内容
set(LIBHELLO_SRC hello.cpp)
add_library(hello SHARED ${LIBHELLO_SRC})

#同时构建静态和动态库
SET(LIBHELLO_SRC hello.cpp)
add_library(hello_static STATIC ${LIBHELLO_SRC})
#对hello_static的重名为hello
SET_TARGET_PROPERTIES(hello_static PROPERTIES  OUTPUT_NAME "hello")
#cmake 在构建一个新的target 时，会尝试清理掉其他使用这个名字的库，因为，在构建 libhello.so 时， 就会清理掉 libhello.a
SET_TARGET_PROPERTIES(hello_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)

add_library(hello SHARED ${LIBHELLO_SRC})
SET_TARGET_PROPERTIES(hello PROPERTIES  OUTPUT_NAME "hello")
SET_TARGET_PROPERTIES(hello PROPERTIES CLEAN_DIRECT_OUTPUT 1)

find_package包含第三方库

find_package（）函数将从CMAKE_MODULE_PATH中的文件夹列表中搜索“ FindXXX.cmake”中的CMake模块。 find_package参数的确切格式取决于要查找的模块。这通常记录在FindXXX.cmake文件的顶部。

find_package(Boost 1.46.1 REQUIRED COMPONENTS filesystem system)

Boost-库名称。这是用于查找模块文件FindBoost.cmake的一部分

1.46.1 - 需要的boost库最低版本

REQUIRED - 告诉模块这是必需的，如果找不到会报错

COMPONENTS - 要查找的库列表。从后面的参数代表的库里找boost
示例：

cmake_minimum_required(VERSION 3.5)

# Set the project name
project (third_party_include)
# find a boost install with the libraries filesystem and system
#使用库文件系统和系统查找boost install
find_package(Boost 1.46.1 REQUIRED COMPONENTS filesystem system)
#这是第三方库，而不是自己生成的静态动态库
# check if boost was found
if(Boost_FOUND)
    message ("boost found")
else()
    message (FATAL_ERROR "Cannot find Boost")
endif()

# Add an executable
add_executable(third_party_include main.cpp)

# link against the boost libraries
target_link_libraries( third_party_include
    PRIVATE
        Boost::filesystem
)

找到包后，它会自动导出变量，这些变量可以通知用户在哪里可以找到库，头文件或可执行文件。与XXX_FOUND变量类似，它们与包绑定在一起，通常记录在FindXXX.cmake文件的顶部。如Boost_INCLUDE_DIRS - boost头文件的路径

三、CMake语法

1.语法的基本原则

变量使用${}方式取值，但是在 IF 控制语句中是直接使用变量名
指令(参数 1 参数 2…) 参数使用括弧括起，参数之间使用空格或分号分开。以上面的 add_executable 指令为例，如果存在另外一个 func.cpp 源文件
就要写成：add_executable(hello main.cpp func.cpp)或者add_executable(hello main.cpp;func.cpp)
指令是大小写无关的，参数和变量是大小写相关的

2.语法注意事项

set(SRC_LIST main.cpp) 可以写成 set(SRC_LIST “main.cpp”)，如果源文件名中含有空格，就必须要加双引号
add_executable(hello main) 后缀可以不写，他会自动去找.c和.cpp，最好不要这样写，可能会有这两个文件main.cpp和main

3.内部构建和外部构建

内部构建，他生产的临时文件特别多，不方便清理
外部构建，就会把生成的临时文件放在build目录下，不会对源文件有任何影响，强烈使用外部构建方式
1、建立一个build目录，可以在任何地方，建议在当前目录下
2、进入build，运行cmake … 当然…表示上一级目录，你可以写CMakeLists.txt所在的绝对路径，生产的文件都在build目录下了
3、在build目录下，运行make来构建工程

四、CMake构建级别

CMake具有许多内置的构建配置，可用于编译工程。这些配置指定了代码优化的级别，以及调试信息是否包含在二进制文件中。这些优化级别，主要有：

Release —— 不可以打断点调试，程序开发完成后发行使用的版本，占的体积小。它对代码做了优化，因此速度会非常快，在编译器中使用命令： -O3 -DNDEBUG 可选择此版本。
Debug ——调试的版本，体积大。在编译器中使用命令： -g 可选择此版本。
MinSizeRel——最小体积版本。在编译器中使用命令：-Os -DNDEBUG可选择此版本。
RelWithDebInfo—— 既优化又能调试。在编译器中使用命令：-O2 -g -DNDEBUG可选择此版本。

在命令行运行CMake的时候，使用cmake命令行的-D选项配置编译类型

cmake .. -DCMAKE_BUILD_TYPE=Release

示例：

cmake_minimum_required(VERSION 3.5)
#如果没有指定则设置默认编译方式
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  #在命令行中输出message里的信息
  message("Setting build type to 'RelWithDebInfo' as none was specified.")
  #不管CACHE里有没有设置过CMAKE_BUILD_TYPE这个变量，都强制赋值这个值为RelWithDebInfo
  set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)

  # 当使用cmake-gui的时候，设置构建级别的四个可选项
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
    "MinSizeRel" "RelWithDebInfo")
endif()


project (build_type)
add_executable(cmake_examples_build_type main.cpp)

本文章为转载内容，我们尊重原作者对文章享有的著作权。如有内容错误或侵权问题，欢迎原作者联系我们进行内容更正或删除文章。