相比Windows Vista & Windows Server2008,Windows7和Windows Server 2008 r2 启动时按F8出现菜单会多出一个菜单项,“修复计算机”, BCD文件也多出了 recoverysequence & recoveryenabled ,它实质是一个Windows Recovery Environment系统恢复环境。
可以使用命令bcdedit /displayorder {05ef5750-78da-11de-9f1a-fc76848d1136} /addfirst将Windows Recovery Environment增加到启动菜单。
然而我们怎样在Windows Vista & Windows Server2008增加这项功能呢?当这项功能损坏或丢失时,我们该怎样修复呢?
从上图我们分析,它调用winre.wim这个文件,同时还用另外一个文件boot.sdi。为了充分这项功能,我首先用Diagnostics and Recovery Toolset生成DaRT6.0光盘ISO文件,然后将这个ISO文件中的sources\boot.wim和boot.sdi复制到c:下,并将boot.wim更名为WinRE.WIM。运行下列脚本文件
 
echo off
       
        :START
            set /P DRIV=      请输入WinRE.WIM文件所在磁盘的盘符(不要冒号如C):
            set DRIVE=%DRIV%:
            IF EXIST %DRIVE%\WINRE.WIM GOTO CREATE_WIM_BCD_ENTRY
            ECHO      盘符输入错误!请重新输入!
            GOTO START
        :CREATE_WIM_BCD_ENTRY
            set RAMDISK_OPTIONS={05ef5751-78da-11de-9f1a-fc76848d1136}
            set WINPE_GUID={05ef5750-78da-11de-9f1a-fc76848d1136}
            set BCDEDIT=bcdedit.exe
            set MAINOS={default}
            %BCDEDIT% -create %RAMDISK_OPTIONS% -d "Repair Computer" -device
            %BCDEDIT% -set %RAMDISK_OPTIONS% ramdisksdidevice partition="%DRIVE%"
            %BCDEDIT% -set %RAMDISK_OPTIONS% ramdisksdipath \boot.sdi
            %BCDEDIT% -create %WINPE_GUID% -d "Windows Recovery Environment" -application OSLOADER
            %BCDEDIT% -set %WINPE_GUID% device ramdisk=[%DRIVE%]\winre.wim,%RAMDISK_OPTIONS%
            %BCDEDIT% -set %WINPE_GUID% path \windows\system32\winload.exe
            %BCDEDIT% -set %WINPE_GUID% osdevice ramdisk=[%DRIVE%]\winre.wim,%RAMDISK_OPTIONS%
            %BCDEDIT% -set %WINPE_GUID% systemroot \windows
            %BCDEDIT% -set %WINPE_GUID% detecthal yes
            %BCDEDIT% -set %WINPE_GUID% nx optin
            %BCDEDIT% -set %WINPE_GUID% winpe yes
            %BCDEDIT% -set %WINPE_GUID% custom:46000010 yes
            %BCDEDIT% -set %MAINOS% recoverysequence %WINPE_GUID%
            %BCDEDIT% -set %MAINOS% recoveryenabled yes
            echo  WinRE配置成功,按任意键退出!
            pause >nul
            exit.
启动计算机后,F8会出现的菜单会多出一个菜单项“修复计算机”
关于Bcdedit.exe使用,参见Server 2008 R2 之十九BCDEDIT的使用