awk常用内置变量:
FS: field separator(输入字段分隔符),默认是空白字符
OFS:output field separator,输出字段分隔符
NF:Number of Field,当前记录的field个数
RS: Record separator(记录分隔符),默认是换行符
NR: The number of input records,awk命令所处理的记录数;如果有多个文件,这个数目会把处理的多个文件中行统一计数
FNR: 与NR不同的是,FNR用于记录正处理的行是当前这一文件中被总共处理的行数
 
awk命令的使用格式:
# awk [options] 'script' file1,file2,...
# awk [options] 'PATTERN { action }' file1,file2,...
根据指定的分隔符将读入的文本切片,默认分隔符为空格,引用第一段$1,引用第二段$2,...引用全部字段$0
用法示例:
[root@rs1 test]# awk '{print $1}' a.txt
[root@rs1 test]# df -hP | awk '{print $1}'
awk中字段分隔符的指定方式:
1、[root@rs1 ~]# awk -F : '{print $1}' /etc/passwd 指定以”:“为分隔符
2、[root@rs1 test]# awk -v FS=: '{print $NF}' /etc/passwd指定以”:“为分隔符 -v表示声明一个变量
3、[root@rs1 ~]# awk 'BEGIN{FS=":"}{print $1,$3}' /etc/passwd在命令执行之前为变量赋值
4、[root@rs1 test]# awk -v OFS=: '{print $1,$2}' a.txt OFS 指定输出字段分隔符
一、print子命令的用法
print的使用格式:
 print item1, item2, ...
要点:
1、各项目之间使用逗号隔开,而输出时则以空白字符分隔
2、输出的item可以为字符串或数值、当前记录的字段(如$1)、变量或awk的表达式;数值会先转换为字符串,而后再输出
3、print命令后面的item可以省略,此时其功能相当于print $0, 因此,如果想输出空白行,则需要使用print ""
用法示例:
# awk 'BEGIN { print "line one\nline two\nline three" }'
# awk -F: '{ print $1, $2 }' /etc/passwd
 
二、printf
printf命令的使用格式:
printf format, item1, item2, ...
要点:
1、其与print命令的最大不同是,printf需要指定format
2、format用于指定后面的每个item的输出格式
3、printf语句不会自动打印换行符,换行时在模式中指定\n
format格式的指示符都以%开头,后跟一个字符,如下:
%c: 显示字符的ASCII码;
%d, %i:十进制整数;
%e, %E:科学计数法显示数值;
%f: 显示浮点数;
%g, %G: 以科学计数法的格式或浮点数的格式显示数值;
%s: 显示字符串;
%u: 无符号整数;
%%: 显示%自身;
修饰符:
N(数字): 显示宽度;
-: 左对齐;
+:显示数值符号;
用法示例:
# awk -F: '{printf "%-15s %i\n",$1,$3}' /etc/passwd
[root@rs1 test]# awk '{printf "%-10s%s\n",$1,$2}' a.txt
三、输出重定向
print items > output-file 保存到某文件中
print items >> output-file 追加到某文件中
print items | command 使用管道交给某些命令处理
特殊文件描述符:
/dev/stdin:标准输入
/dev/sdtout: 标准输出
/dev/stderr: 错误输出
/dev/fd/N: 某特定文件描述符,如/dev/stdin就相当于/dev/fd/0
用法示例:
# awk -F: '{printf "%-15s %i\n",$1,$3 > "/dev/stderr" }' /etc/passwd
awk中常见的模式类型:
1、Regexp: 正则表达式,格式为/regular expression/
2、expresssion:表达式,其值非0或为非空字符时满足条件,如:$1 ~ /foo/ 或 $1 == "magedu",用运算符~(匹配)和~!(不匹配)
3、Ranges: 指定的匹配范围,格式为pat1,pat2  /bash/,/awk/从被/bash/匹配到的行开始到被/awk/匹配到的行结束
4、BEGIN/END:特殊模式,仅在awk命令执行前运行一次或结束前运行一次
5、Empty(空模式):匹配任意输入行
用法示例:
[root@rs1 test]# awk 'BEGIN{print "a" "b"}'字符串操作符,将两个字符串直接连接
[root@rs1 test]# awk -F: '$1 ~ /^root/ {print $3,$4,$NF}' /etc/passwd 显示被模式匹配到的行的第三第四和最有一个字段
[root@rs1 test]# awk -F: '$1 !~ /^root/ {print $3,$4,$NF}' /etc/passwd不能被模式匹配
[root@rs1 test]# awk -F: '/bash/{print $0}' /etc/passwd
[root@rs1 test]# awk -F: '$3>=500{print $1,$3}' /etc/passwd
[root@rs1 ~]# awk -F: 'BEGIN{print "Username       UID"}{printf "%-15s%s\n",$1,$3}END{print "Over"}' /etc/passwd
 
awk中的控制语句:
1、if-else
语法:if (condition) {then-body} else {[ else-body ]}
例子:
awk -F: '{if ($1=="root") print $1, "Admin"; else print $1, "Common User"}' /etc/passwd
awk -F: '{if ($1=="root") printf "%-15s: %s\n", $1,"Admin"; else printf "%-15s: %s\n", $1, "Common User"}' /etc/passwd
awk -F: -v sum=0 '{if ($3>=500) sum++}END{print sum}' /etc/passwd
2、while
语法: while (condition){statement1; statment2; ...}
[root@rs1 ~]# awk -F: '$1!~/root/{i=1;while (i<=4) {print $i;i++}}' /etc/passwd
[root@rs1 ~]# awk -F: '$1!~/root/{i=1;while (i<=NF) {print $i;i+=2}}' /etc/passwd只显示奇数字段
3、do-while
语法: do {statement1, statement2, ...} while (condition)
 
4、for
语法: for ( variable assignment; condition; iteration process) { statement1, statement2, ...}
for循环还可以用来遍历数组元素:
语法: for (i in array) {statement1, statement2, ...}
遍历数组中的每一个元素
for {A in ARRAY} {print ARRAY[A]}
 A中保存数组下标
[root@rs1 ~]# awk 'BEGIN{A["m"]="hello";A["n"]="world";for (B in A) print A[B]}' B中保留数组A的下标
[root@rs1 ~]# awk -F: '{for(i=1;i<=NF;i+=2) print $i}' /etc/passwd
[root@rs1 ~]# netstat -ant | awk '$1~/tcp/{S[$NF]++}END{for (A in S) print A,S[A]}'
[root@rs1 ~]# awk -F: '$NF!~/^$/{SHELL[$NF]++}END{for(A in SHELL) print A,SHELL[A]}' /etc/passwd
[root@rs1 httpd]# awk '{IP[$1]++}END{for (A in IP) print A,IP[A]}' access_log.1
5、case
语法:switch (expression) { case VALUE or /REGEXP/: statement1, statement2,... default: statement1, ...}
6、break 和 continue
常用于循环或case语句中
7、next
提前结束对本行文本的处理,并接着处理下一行
 
awk中使用数组:
array[index-expression]
index-expression可以使用任意字符串;需要注意的是,如果某数据组元素事先不存在,那么在引用其时,awk会自动创建此元素并初始化为空串;因此,要判断某数据组中是否存在某元素,需要使用index in array的方式。
用法示例:
netstat -n | awk '/^tcp/ {++S[$NF]} END {for(a in S) print a, S[a]}'
每出现一被/^tcp/模式匹配到的行,数组S[$NF]就加1,NF为当前匹配到的行的最后一个字段,此处用其值做为数组S的元素索引;
awk '{counts[$1]++}; END {for(url in counts) print counts[url], url}' /var/log/httpd/access_log
用法与上一个例子相同,用于统计某日志文件中IP地的访问量
 
awk的内置函数:
split(string, array [, fieldsep [, seps ] ])
功能:将string表示的字符串以fieldsep为分隔符进行分隔,并将分隔后的结果保存至array为名的数组中;
netstat -ant | awk '/:80/{split($5,clients,":");IP[clients[1]]++}END{for(i in IP){print IP[i],i}}' | sort -rn | head -50
length([string])
功能:返回string字符串中字符的个数;
substr(string, start [, length])
功能:取string字符串中的子串,从start开始,取length个;start从1开始计数;
system(command)
功能:执行系统command并将结果返回至awk命令
systime()
功能:取系统当前时间